!**************************************************************************************!
! TITLE: CFVR1246 -  Shear design according to Eurocode 2 (2008)
! SUBTITLE: Design a concrete reinforced beam subjected to Shear force according to Eurocode 2 (2008)
!
! DESCRIPTION: A 5m length cantilever has a T concrete reinforced section
! DESCRIPTION: and is subjected to a uniform distributed load of 84 kN/m.
! DESCRIPTION:
! DESCRIPTION: The aim of the example is to obtain the necessary steel amount according to Eurocode 2 (2008).
!
! ELEMENT TYPE: BEAM3
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Code Checking/Design
! KEYWORD4: Reinforced Concrete
! KEYWORD5: Eurocode 2
!
!**************************************************************************************!
   FINISH
  ~CFCLEAR,,1
   NomFile='CFVR1246'
 /TITLE,%NomFile% Shear design according to Eurocode 2 (2008)

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,,LENG,M
  ~UNITS,,TIME,S
  ~UNITS,,FORC,KN
  ~CODESEL,EC3-92,EC2-08,EC2-08,,EC8-94

! Preprocessor
  /PREP7

! Parameters
  L=5          ! Length between supports, in m
  Q=84         ! Uniform distributed load in kN/m

! Material Definition
 ~CFMP,1,LIB,CONCRETE,EC2,C25/30
 ~CFMP,2,LIB,REINF,EC2,S500

! Element Type Definition
  ET,1,Beam3                           ! Element Type 1: 2D Beam

! Cross-section definition
 ~CSECDMS,1,T,1,0.375,0.15,0.75,0.15   ! T Section
! Reinforcement definition
 ~RNFDEF,1,1,2,1,1,0.02,22E-4          ! Longitudinal reinforcement
 ~RNFMDF,1,1,UFC,2
 ~RNFDEF,1,SHEAR,2,,,10.94E-4          ! Shear reinforcement
! Code properties definition
 ~SECMDF,1,EC2PROP ,REC   ,,0.05       ! 5 cm Cover
 ~SECMDF,1,EC2PROP ,KEYAST,,0
 ~SECMDF,1,EC2PROP ,RHO1  ,,0.045
! Beam properties
  ~BMSHPRO,1,BEAM,1,1,,,3,1,,,

! Model Construction
  N,1                                   ! Nodes input
  N,2,L/2
  N,3,3*L/4
  N,4,L

  E,1,2                                 ! Elements input
  E,2,3
  E,3,4

  D,1,ALL                               ! Constraint conditions

/SOLU
  SFBEAM,ALL,1,PRES,Q
  SOLVE               ! Calculation

/POST1

! Postprocessor
  ~CFSET,,1,1       ! Read first load step

! Shear design
  ~DIMCON,SHT,SHEAR

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 10
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'VRDC'
  LABEL(2,1) = 'VRDS'
  LABEL(3,1) = 'DSG_CRT'
  LABEL(4,1) = 'VRDC'
  LABEL(5,1) = 'VRDS'
  LABEL(6,1) = 'DSG_CRT'
  LABEL(7,1) = 'VRDC'
  LABEL(8,1) = 'VRDS'
  LABEL(9,1) = 'ASSH'
  LABEL(10,1) = 'DSG_CRT'

! Correct values
  VALUE(1,1)=38.46
  VALUE(2,1)=197.437
  VALUE(3,1)=0.0
  VALUE(4,1)=38.46
  VALUE(5,1)=197.437
  VALUE(6,1)=0.0
  VALUE(7,1)=38.46
  VALUE(8,1)=105.000
  VALUE(9,1)=8.26E-4
  VALUE(10,1)=1.00

! Comparison
 ~PLLSCON,VRDC
  *GET,VALUE(1,2),ELEM,2,ETAB,CFETAB_I
  *GET,VALUE(4,2),ELEM,1,ETAB,CFETAB_I
  *GET,VALUE(7,2),ELEM,3,ETAB,CFETAB_I
 ~PLLSCON,VRDS
  *GET,VALUE(2,2),ELEM,2,ETAB,CFETAB_I
  *GET,VALUE(5,2),ELEM,1,ETAB,CFETAB_I
  *GET,VALUE(8,2),ELEM,3,ETAB,CFETAB_I
 ~PLLSCON,ASSH
  *GET,VALUE(9,2),ELEM,3,ETAB,CFETAB_I
 ~PLLSCON,DSG_CRT
  *GET,VALUE(3,2),ELEM,2,ETAB,CFETAB_I
  *GET,VALUE(6,2),ELEM,1,ETAB,CFETAB_I
  *GET,VALUE(10,2),ELEM,3,ETAB,CFETAB_I

! Warning and error tolerances
  *DO,II,1,NComp
    TOLER(II,1)= 1E-02 $ TOLER(II,2)= 1E-02
  *ENDDO
  TOLER( 9, 1)= 1E-06 $ TOLER( 9, 2)= 1E-06

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC