!*************************************************************************************!
! TITLE: CFVR1249 - Cracking checking according to Eurocode 2 (2008)
! SUBTITLE: check a reinforced concrete beam by cracking according to Eurocode 2 (2008)
!
! DESCRIPTION: A fixed beam which has a rectangular reinforced concrete section is subjected to
! DESCRIPTION: a bending moment of 300 kN*m on the Y axis direction.
! DESCRIPTION:
! DESCRIPTION: The aim of the example is to obtain the check criterion according to Eurocode 2 (2008).
! DESCRIPTION:
! DESCRIPTION: This example is based on EXAMPLE 7.3 of the EUROCODE 2 WORKED
! DESCRIPTION: EXAMPLES of the European Concrete Platform.
!
! ELEMENT TYPE: BEAM44
! MODULES:
! UNITS:SI
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Code Checking/Design
! KEYWORD4: Reinforced Concrete
! KEYWORD5: Eurocode 2
!
!*************************************************************************************!
  FINISH
  ~CFCLEAR,,1
  NomFile='CFVR1249'
  /TITLE,%NomFile%, Cracking checking according to Eurocode 2 (2008)

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
 ~UNITS,SI
 ~CODESEL,EC3-92,EC2-08,EC2-08,,EC8-94

! Preprocessor
  /PREP7

! Material Definition
 ~CFMP,1,LIB,CONCRETE,EHE,HA-30
 ~CFMP,1,EC2_C,TSDSSD,,2 
 ~CFMP,1,EC2_C,GAMc,,1.0
 ~CFMP,1,EC2_C,ALP ,,1.0

 ~CFMP,2,LIB,REINF,EHE,B500S
 ~CFMP,2,EC2_S,GAMs,,1

! Element Type Definition
  ET,1,Beam44

! Cross-section definition
  ~CSECDMS,1,REC,1,0.6,0.4,,,,,,,1,2
  ~RNFMDF,1,RBDEF,RMAT,2
  ~RNFMDF,1,RBDEF,RKEY,0
  ~RNFMDF,1,1,FI,12
  ~RNFMDF,1,1,N,4
  ~RNFMDF,1,2,FI,24
  ~RNFMDF,1,2,N,6
  ~SECMDF,1,EC2PROP,RHOr,,2712/(400*600)/0.2012,2

! Beam & Shell property
 ~BMSHPRO,1,BEAM,1,1,,,44,,,,

! Model Construction
  N,1                         ! Nodes input
  N,5,5
  FILL,1,5

  E,1,2                       ! Elements input
  EGEN,4,1,1,1

  D,1, , , , , ,ALL           ! Constraint conditions

/SOLU
  Mz = 3e5            ! Mz Bending moment
  My = 0.0            ! My Bending moment
  N  = 0              ! Axial force
  F,5,FX,N
  F,5,MZ,Mz
  F,5,MY,My
  SOLVE               ! Load Step 1

/POST1

! Postprocessor
  ~CFSET,,1,1       ! Read first load step
  ~CHKCON,CRACK, ,0,0.0001,,0.6   ! Alernative 1

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 5
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
!--------------------------------------------------------------------------------------
  LABEL( 1)  = 'SRMAX'
  LABEL( 2)  = 'WK'
  LABEL( 3)  = 'SIGMA'
  LABEL( 4)  = 'POS'
  LABEL( 5)  = 'CRT'

! Correct data, obtained data
!--------------------------------------------------------------------------------------
  ! Alternative 1
  ~CFSET,1
  ~PLLSCON,SRMAX,1,
  VALUE( 1,1) = 208.64E-3           $  *GET,VALUE( 1,2),ELEM,3,ETAB,CFETAB_I
  ~PLLSCON,WK,1,
  VALUE( 2,1) = 0.184E-3            $  *GET,VALUE( 2,2),ELEM,3,ETAB,CFETAB_I
  ~PLLSCON,SIGMA,1,
  VALUE( 3,1) = 234e6               $  *GET,VALUE( 3,2),ELEM,3,ETAB,CFETAB_I
  ~PLLSCON,POS,1,
  VALUE( 4,1) = -1                  $  *GET,VALUE( 4,2),ELEM,3,ETAB,CFETAB_I
  ~PLLSCON,CRT_TOT,1,
  VALUE( 5,1) = 0.184E-3/0.0001     $  *GET,VALUE( 5,2),ELEM,3,ETAB,CFETAB_I

! Warning and error tolerances
  TOLER(1,1) = 1E-3                 $  TOLER(1,2) = 1E-3
  TOLER(2,1) = 1.5E-5               $  TOLER(2,2) = 1.5E-5
  TOLER(3,1) = 1E7                  $  TOLER(3,2) = 1E7
  TOLER(4,1) = 1E-3                 $  TOLER(4,2) = 1E-3
  TOLER(5,1) = 1.5E-1               $  TOLER(5,2) = 1.5E-1

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC