!***************************************************************************************************!
! TITLE: CFVR1439 - Shear design according to EHE-08
! SUBTITLE: Design a reinforced concrete beam subjected to shear force according to EHE-08
!
! DESCRIPTION: A beam which is fixed at the right and simply supported at the left,
! DESCRIPTION: has a rectangular reinforced concrete section
! DESCRIPTION: and it is subjected to a uniform distributed load of 6.75 Mp/m.
! DESCRIPTION:
! DESCRIPTION: The aim of the example is to obtain the necessary steel amount according to EHE-08.
!
! ELEMENT TYPE: BEAM3
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Code Checking/Design
! KEYWORD4: Reinforced Concrete
! KEYWORD5: EHE
!
!***************************************************************************************************!
  FINISH
  ~CFCLEAR,,1
  NomFile='CFVR1439'
  /TITLE,%NomFile%, Shear design according to EHE-08

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
~UNITS,,LENG,M
~UNITS,,TIME,S
~UNITS,,FORC,MP
~CODESEL,EC3-92,EHE-08,,,EC8-94

! Preprocessor
  /PREP7

! Parameters
  L=10         ! Length between supports, in m
  b=.3         ! Cross-section width in m.
  h=.5         ! Depth in m.
  Q=4.5*1.5    ! Uniform distributed load in Mp/m

! Material Definition
 ~CFMP,1,LIB,CONCRETE,EHE,HA-35
 ~CFMP,2,LIB,REINF,EHE,B400S

! Element Type Definition
  ET,1,Beam3                            ! Element Type 1: 2D Beam

! Cross-section definition
 ~CSECDMS,1,REC,1,0.5,0.3

! Reinforcement definition
 ~RNFDEF,1,1,2,4, , ,0.6368E-02    ! Bot. reinf. for bending
 ~RNFDEF,1,2,2,2, , ,0.2283E-02    ! Top reinf. for bending
 ~RNFDEF,1,SHEAR,2, , ,1E-4,  ! Shear reinf.
! Beam & Shell property
 ~BMSHPRO,1,BEAM,1,1,,,3,1,0,,Beam property

! Code properties definition
 ~SECMDF,1,EHEPROP,REC,,5e-002

! Model Construction
  N,1                                   ! Nodes input
  N,21,L
  FILL,1,21
  E,1,2                                 ! Elements input
  EGEN,20,1,1,1
  D,1, , , , , ,UX,UY                   ! Boundary conditions
  D,21, , , , , ,UY

/SOLU
  SFBEAM,ALL,1,PRES,Q
  SOLVE               ! Calculation

/POST1

! Postprocessor
  ~CFSET,,1,1       ! Read first load step

! Shear in Y design according to EHE
  ~DIMCON,SHT,SHEAR

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 4
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
!--------------------------------------------------------------------------------------
  LABEL(1,1) = 'VU1'
  LABEL(2,1) = 'VSU'
  LABEL(3,1) = 'VCU'
  LABEL(4,1) = 'ASSH'

! Correct values
  VALUE(1,1)=96.36
  VALUE(2,1)=25.47
  VALUE(3,1)=4.910
  VALUE(4,1)=1.773E-03

! Comparison
 ~PLLSCON,VU1
 *GET,VALUE(1,2),ELEM,19,ETAB,CFETAB_J
 ~PLLSCON,VSU
 *GET,VALUE(2,2),ELEM,19,ETAB,CFETAB_J
 ~PLLSCON,VCU
 *GET,VALUE(3,2),ELEM,19,ETAB,CFETAB_J
 ~PLLSCON,ASSH
 *GET,VALUE(4,2),ELEM,19,ETAB,CFETAB_J

! Warning and error tolerances
  TOLER( 1, 1)= 1E-01 $ TOLER( 1, 2)= 1E-01
  TOLER( 2, 1)= 1E-01 $ TOLER( 2, 2)= 1E-01
  TOLER( 3, 1)= 1E-02 $ TOLER( 3, 2)= 1E-02
  TOLER( 4, 1)= 1E-05 $ TOLER( 4, 2)= 1E-05

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC