!*************************************************************************************!
! TITLE: CFVR2001 - Alternatives envelope (checking)
! SUBTITLE: Envelope of reinforced concrete checking results on beam elements.
!
! DESCRIPTION: The model is a half frame of 2.0m length and 3.0m height.
! DESCRIPTION:
! DESCRIPTION: It is modeled with beam elements with a rectangular cross section of 0.50m x 0.40m.
! DESCRIPTION:
! DESCRIPTION: The ending nodes are completely restrained.
! DESCRIPTION:
! DESCRIPTION: The applied loads are:
! DESCRIPTION:
! DESCRIPTION: - Load step 1: 40 kN/m<sup>2</sup> on the horizontal top beams.
! DESCRIPTION:
! DESCRIPTION: - Load step 2: 200 kN horizontal force on the corner node.
! DESCRIPTION:
! DESCRIPTION: - Load step 3: 40 kN/m<sup>2</sup> on the vertical top beams.
! DESCRIPTION:
! DESCRIPTION: - Load step 4: 200 kN vertical force on the corner node.
! DESCRIPTION:
! DESCRIPTION: All loadsteps are checked by code and the results of load steps 1 and 3
! DESCRIPTION: are enveloped.
! DESCRIPTION:
! DESCRIPTION: The example is a variation of the problem included in "Hormigón Armado,
! DESCRIPTION: MONTOYA-MESEGUER-CABRE, 1994, PAGE 294, Ex. 1º"
!
! ELEMENT TYPE: Beam3
! MODULES:
! UNITS: User
! KEYWORD1: Combinations
! KEYWORD2: Cross Section
! KEYWORD3: Reinforced Concrete
! KEYWORD4: EHE
!*************************************************************************************!
   FINISH
  ~CFCLEAR,,1
   NomFile='CFVR2001'
   /TITLE, %NomFile%, Alternatives envelope (checking)

! ---------------------------------------------------------------------------------
! Initial data
! ---------------------------------------------------------------------------------
! CivilFEM SETUP
 ~UNITS,,LENG,M
 ~UNITS,,TIME,S
 ~UNITS,,FORC,KN
 ~CODESEL,EC3-92,EHE,,,EC8-94

! Preprocessor
  /PREP7

! Material Definition
 ~CFMP,1,LIB,CONCRETE,EHE,HA-20
 ~CFMP,2,LIB,REINF,EHE,B 400 S

! Element Type Definition
  ET,1,Beam3                            ! Element Type 1: 2D Beam

! Cross-section definition
 ~CSECDMS,1,REC,1,0.50,0.40

! Reinforcement definition
 ~RNFDEF,1,1,2,2,0,0.03,0.4E-04       ! Total Reinf. Area= 4E-4 m^2
 ~RNFDEF,1,2,2,4,0,0.03,0.4E-04       ! Total Reinf. Area= 4E-4 m^2

! Beam & Shell property
 ~BMSHPRO,1,BEAM,1,1,,,3,1,0,,Beam property

! Model Construction
  K,1                                   ! Nodes input
  K,2,,3
  K,3,2,3
  LSTR,1,2
  LSTR,2,3

! Meshing
  ESIZE,1
  LMESH,ALL

/SOLU

  DK,1,ALL
  DK,3,ALL
! Apply loads
! First load step
 W=40                ! 40kN/m2
 ESEL,S,ELEM,,4,5
 SFBEAM,ALL,1,PRES,W
 ESEL,ALL
 SOLVE               ! Calculation
! Second load step
 SFEDELE,ALL,1,PRES
 FK,2,FX,-200
 SOLVE
! Third load step
 FKDELE,ALL,ALL
 P=40                ! 40kN/m2
 ESEL,S,ELEM,,1,3
 SFBEAM,ALL,1,PRES,P
 ESEL,ALL
 SOLVE
! Fourth load step
 SFEDELE,ALL,1,PRES
 FK,2,FY,200
 SOLVE

/POST1
! Postprocessor
  ~CFSET,,1,1       ! Read first load step
  ~DIMCON,2DB,,0,0.5,10   ! 1st Alternative
  ~PLLSCON,REINFACT

  ~CFSET,,2,1       ! Read second load step
  ~DIMCON,2DB,,0,0.5,10   ! 2nd Alternative
  ~PLLSCON,REINFACT

 ~CFSET,,3,1        ! Read third load step
 ~DIMCON,2DB,,0,0.5,10    ! 3rd Alternative
 ~PLLSCON,REINFACT

 ~CFSET,,4,1        ! Read fourth load step
 ~DIMCON,2DB,,0,0.5,15    ! 4th Alternative
 ~PLLSCON,REINFACT

! Reinforcement envelopes
 ~ENVDEF,1,3,2     ! 1st and 3rd Alternatives
 ~ENVELOP,MAX      ! Envelope of maximum values. Alternative 5
 ~ENVELOP,MIN      ! Envelope of minimum values. Alternative 6
 ~ENVELOP,ABS      ! Envelope of absolute maximum values. Alternative 7

! ---------------------------------------------------------------------------------
! DATA CHECK
! ---------------------------------------------------------------------------------
! Data comparison number
  NComp = 3
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'CRTC2D_I'
  LABEL(2,1) = 'CRTC2D_J'

! Correct values
  VALUE(1,1)=0.717669
  VALUE(2,1)=0.575812
  VALUE(3,1)=0.717669

! Comparison
 ~CFSET,5
 ~CFGET,VALUE(1,2),ELEMENT,4,RESULT,REINFACT,I
 ~CFSET,6
 ~CFGET,VALUE(2,2),ELEMENT,4,RESULT,REINFACT,I
 ~CFSET,7
 ~CFGET,VALUE(3,2),ELEMENT,4,RESULT,REINFACT,I

! Warning and error tolerances
  TOLER( 1, 1)= 2E-03 $ TOLER( 1, 2)= 1E-03
  TOLER( 2, 1)= 3E-03 $ TOLER( 2, 2)= 1E-03
  TOLER( 3, 1)= 2E-03 $ TOLER( 3, 2)= 1E-03

! ---------------------------------------------------------------------------------
! Results comparison
! ---------------------------------------------------------------------------------
  COMPARA.MAC