!*************************************************************************************!
! TITLE: CFVR2201 - Reinforced concrete checking according to British Standard 8110
! SUBTITLE: Bending & axial force checking.
!
! DESCRIPTION: A concrete cantilever beam with rectangular shape section and reinforcement
! DESCRIPTION: uniformly distributed at top and bottom faces is subjected to an axial
! DESCRIPTION: compression force and moment at free end.
! DESCRIPTION:
! DESCRIPTION: Determine the total criterion according to BS 8110.
! DESCRIPTION:
!
! ELEMENT TYPE: BEAM3
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Code Checking/Design
! KEYWORD4: Reinforced Concrete
! KEYWORD5: BS 8110
!
!*************************************************************************************!
  FINISH
  ~CFCLEAR,,1
  NomFile='CFVR2201'
  /TITLE, %NomFile%, BENDING + AXIAL FORCE CHECKING ACCORDING TO BS8110

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,,LENG,M
  ~UNITS,,TIME,S
  ~UNITS,,FORC,KN
  ~CODESEL,,BS8110

! Preprocessor
  /PREP7

! Material Definition
  ~CFMP,1,LIB,CONCRETE,BS8110,C20
  ~CFMP,2,LIB,REINF,BS8110,Gr460A

! Element Type Definition
  ET,1,Beam3                            ! Element Type 1: 2D Beam

! Cross-section definition
 ~CSECDMS,1,REC,1,0.5,0.3

! Reinforcement definition
 ~RNFDEF,1,1,2,2,0,0.03,0.4423E-03 !Top reinf.
 ~RNFDEF,1,2,2,4,0,0.03,0.2193E-02 !Bottom reinf.

! Beam & Shell property
 ~BMSHPRO,1,BEAM,1,1,,,3,1,0,,Beam property

! Model
  N,1
  N,5,5
  FILL,1,5
  E,1,2
  EGEN,4,1,1,1
! Boundary conditions
  D,1,ALL,0

/SOLU
! Solution
  M=306               ! 306 KN*m bending moment
  H=-200              ! 200 kN axial compression force
  F,5,FX,H
  F,5,MZ,M
  SOLVE

/POST1
! Postprocessor
  ~CFSET,,1,1       ! Read first load step

! Bending + Axial checking
  ~CHKCON,2DB,,0

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparision number
  NComp = 2
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'CRTC2D_I'
  LABEL(2,1) = 'CRTC2D_J'

! Correct Values
  VALUE(1,1) = 1.080
  VALUE(2,1) = 1.080

! Comparison
 ~PLLSCON,CRT_TOT
 *GET,VALUE(1,2),ELEM,4,ETAB,CFETAB_I
 ~PLLSCON,CRT_TOT
 *GET,VALUE(2,2),ELEM,4,ETAB,CFETAB_J

! Warning and error tolerances
  TOLER( 1,1)= 1E-2 $ TOLER( 1,2)= 1E-2
  TOLER( 2,1)= 1E-2 $ TOLER( 2,2)= 1E-2

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC