!***************************************************************************************************!
! TITLE: CFVR2710 - Torsion checking according to AS3600
! SUBTITLE: Check a reinforced concrete beam subjected to torsional moment according to AS3600
!
! DESCRIPTION: A fixed beam which has a rectangular reinforced concrete section is subjected to
! DESCRIPTION: shear force of 7.52 Mp and a torsional moment of 1.52 Mp*m.
! DESCRIPTION:
! DESCRIPTION: The aim of the example is to obtain the check criterion according to AS3600.
! DESCRIPTION:
! DESCRIPTION: Variation of the example included in "Prontuario informático del H.A."
! DESCRIPTION: by Corres-León-Pérez-Arroyo-López, 1994, Page 227
! DESCRIPTION:
!
! ELEMENT TYPE: BEAM4
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Code Checking/Design
! KEYWORD4: Reinforced Concrete
! KEYWORD5: AS3600
!
!***************************************************************************************************!
   FINISH
  ~CFCLEAR,,1

   NomFile='CFVR2710'
 /TITLE,%NomFile%, TORSION CHECKING ACCORDING TO AS3600

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
~UNITS,,LENG,M
~UNITS,,TIME,S
~UNITS,,FORC,MP
~CODESEL,EC3-92,AS3600,,,EC8-94

! Preprocessor
  /PREP7

! Parameters
  L=1              ! Length in m
  b=.4             ! Cross-section width in m.
  h=.3             ! Depth in m.
  T=0.95*1.6       ! Torsional moment in Mp*m
  Q=4.7*1.6        ! Maximum concomitant design shear force in Mp

! Material Definition
 ~CFMP,1,LIB,CONCRETE,ACI,fc_3500
 ~CFMP,2,LIB,REINF,ACI,fy_60000

! Element Type Definition
  ET,1,Beam4                           ! Element Type 1: 2D Beam

! Cross-section definition
 ~CSECDMS,1,REC,1,0.3,0.4
! Reinforcement definition
 ~RNFDEF,1,TORSION,2,3.03e-4, , , ,3.27e-4
! Beam properties
 ~BMSHPRO,1,BEAM,1,1,,,4,0,0,,Beam Properties

! Model
  N,1                                  ! Nodes input
  N,5,L
  FILL,1,5
  E,1,2                                ! Elements input
  EGEN,4,1,1,1
  D,1, , , , , ,ALL                    ! Boundary conditions

FINISH
/SOLU
  F,5,FY,-Q
  F,5,MX,T
  SOLVE               ! Calculation


/POST1
! Postprocessor
  ~CFSET,,1,1       ! Read first load step
! Torsion checking according to AS3600
  ~CHKCON,SHT,TORSION

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 9
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'TUMAX'
  LABEL(2,1) = 'TUC'
  LABEL(3,1) = 'TUS'
  LABEL(4,1) = 'ATL'
  LABEL(5,1) = 'CRTTUMAX'
  LABEL(6,1) = 'CRTTUC'
  LABEL(7,1) = 'CRTTUS'
  LABEL(8,1) = 'CRTATL'
  LABEL(9,1) = 'CRT_TOT'

! Correct values
  VALUE(1,1)= 1.7623536
  VALUE(2,1)= 0.536257427
  VALUE(3,1)= 1.799670682
  VALUE(4,1)= 0.00016362
  VALUE(5,1)= 1.232118555
  VALUE(6,1)= 4.049227966
  VALUE(7,1)= 1.206569954
  VALUE(8,1)= 5.00E-01
  VALUE(9,1)= 1.232118555

! Comparison
  ~CFGET,VALUE(1,2),ELEMENT,1,RESULT,TUMAX,I
  ~CFGET,VALUE(2,2),ELEMENT,1,RESULT,TUC   ,I
  ~CFGET,VALUE(3,2),ELEMENT,1,RESULT,TUS   ,I
  ~CFGET,VALUE(4,2),ELEMENT,1,RESULT,ATL   ,I
  ~CFGET,VALUE(5,2),ELEMENT,1,RESULT,CRTTUMAX,I
  ~CFGET,VALUE(6,2),ELEMENT,1,RESULT,CRTTUC ,I
  ~CFGET,VALUE(7,2),ELEMENT,1,RESULT,CRTTUS ,I
  ~CFGET,VALUE(8,2),ELEMENT,1,RESULT,CRTATL ,I
  ~CFGET,VALUE(9,2),ELEMENT,1,RESULT,CRT_TOT ,I

! Warning and error tolerances
  *DO,II,1,9
    TOLER(II, 1)= 1E-03
    TOLER(II, 2)= 1E-03
  *ENDDO
	TOLER(4, 1)= 1E-07     $    TOLER(4, 2)= 1E-07

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC