!*************************************************************************************!
! TITLE: CFVR3208 - Slope stability from FEM analysis
! SUBTITLE: Slope stability analysis from FEM analysis results.
!
! DESCRIPTION: A plane model as shown in the figure is used to check the slope stability analysis
! DESCRIPTION: from FEM analysis results.
! DESCRIPTION:
! DESCRIPTION: The model is made off four layers of materials with the following dry specific
! DESCRIPTION: weight (from top to bottom):
! DESCRIPTION:
! DESCRIPTION: - 12600 N/m<sup>2</sup>
! DESCRIPTION:
! DESCRIPTION: - 14400 N/m<sup>2</sup>
! DESCRIPTION:
! DESCRIPTION: - 11200 N/m<sup>2</sup>
! DESCRIPTION:
! DESCRIPTION: - 9000 N/m<sup>2</sup>
! DESCRIPTION:
! DESCRIPTION: The terrain is considered dry. No water table is defined.
! DESCRIPTION:
! DESCRIPTION: The only action on the structure is its self weight.
!
! ELEMENT TYPE: PLANE82
! MODULES: GETC
! UNITS: SI
! KEYWORD1: Geotechnics
! KEYWORD2: Slope Stability
!*************************************************************************************!
  FINISH
  ~CFCLEAR,,1
  ~CFACTIV,GETC,Y
  NomFile='CFVR3208'
  /TITLE, %NomFile%, Slope stability (FEM analysis)

! -------------------------------------------------------------------------------------
! 1. Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,SI

/PREP7
! 2. Materials
! --------------------------------------------------
~CFMP,1,LIB,SOIL,,OH
~CFMP,2,LIB,SOIL,,CH
~CFMP,3,LIB,SOIL,,SC
~CFMP,4,LIB,SOIL,,PH
~CFMP,1,Soil,GAMD,,12600 ! OH
~CFMP,2,Soil,GAMD,,14400 ! CH
~CFMP,3,Soil,GAMD,,11200 ! SC
~CFMP,4,Soil,GAMD,,9000  ! PH

! 3. Elements
! --------------------------------------------------
ET,1,PLANE82

! 4. Model
! --------------------------------------------------
K, 1,-12,28
K, 2,  1,29
K, 3, 10,37
K, 4, 19,38
K, 5, 35,28
K, 6, 50,27
K, 7,  6,33
K, 8, 20,29
K, 9, 26,34
K,10, 18,24
K,11, 50,21
K,12,-12,19
K,13, 50,16
K,14,-12, 6
K,15, 50,10
A,7,8,9,4,3
A,2,7,8,9,5,6,11,10
A,1,2,10,11,13,12
A,15,13,12,14

AESIZE,ALL,3

*DO,I,1,4
  MAT,I
  AMESH,I
*ENDDO
/NUMBER,1
/PNUM,MAT,1
EPLOT
/IMAGE, SAVE, %NomFile%,BMP

! 5. Capturing Model
! --------------------------------------------------
pp1=node(kx(1),ky(1),kz(1))
pp2=node(kx(6),ky(6),kz(6))
pp3=node(kx(5),ky(5),kz(5))
~SLPIN,PP1,PP2,PP3

! 6. Circles Centres Grid Input
! --------------------------------------------------
K,16,21,41
K,17,35,32
K,18,42,43
k,19,28,52
~SLPCIRK,16,19,17,5,6

! 7. Tangents Input
! --------------------------------------------------
K,20,34,27
K,21,34,11
K,22, 0,11
K,23,18,37
~SLPTANK,20,23,22,21,10

! 8. Solve
! --------------------------------------------------
/SOLU
ALLS
KSEL,S,,,14,15
LSLK,S,1
NSLL,S
D,ALL,ALL,0
ALLS
ACEL,,9.8
SOLVE

/POST1
~SLPOPT,,,,,2
~SLPSOL,10

!--------------------------------------------------------------------------------------
! 9. Data Check
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp    = 3
  NComp_ch = 0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

!--------------------------------------------------------------------------------------
! 10. Labels, Correct data, obtained data
!--------------------------------------------------------------------------------------

  VALUE(  1,1) =  1.535
  LABEL(  1) = 'FEM262'
  ~CFGET,VALUE(  1,2),SLOPE,,RES,F,,2,262
  VALUE(  2,1) =  1.559
  LABEL(  2) = 'FEM202'
  ~CFGET,VALUE(  2,2),SLOPE,,RES,F,,2,202
  VALUE(  3,1) =  1.686
  LABEL(  3) = 'FEM152'
  ~CFGET,VALUE(  3,2),SLOPE,,RES,F,,2,152

! Warning and error tolerances
  *DO,II,1,NComp
    TOLER(II,1) = VALUE(II,1)*0.12
    TOLER(II,2) = VALUE(II,1)*0.12
  *ENDDO

!--------------------------------------------------------------------------------------
! 11. Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC