!*************************************************************************************!
! TITLE: CFVR3217 - Slope stability with non horizontal reinforced earth
! SUBTITLE: Slope stability analysis, without water pressure and with reinforced earth.
!
! DESCRIPTION: A plane model as shown in the figure is used to check reinforced earth in
! DESCRIPTION  slope stability analysis.
! DESCRIPTION: Janbu method is used.
! DESCRIPTION:
! DESCRIPTION: The model is made off a single material with a dry specific
! DESCRIPTION: weight of 20000 N/m<sup>2</sup>, 28º internal friction angle and no cohesion.
! DESCRIPTION:
! DESCRIPTION: The terrain is considered dry. No water table is defined.
! DESCRIPTION:
! DESCRIPTION: The only action on the structure is its self weight and the reinforcement bars which
! DESCRIPTION: are defined as a group of two bars with 0.3 as the apparent friction coefficient,
! DESCRIPTION: with a 30º slope downwards.
! DESCRIPTION: The bars are assumed to have no strength limit.
!
! ELEMENT TYPE: PLANE42
! MODULES: GETC
! UNITS: SI
! KEYWORD1: Geotechnics
! KEYWORD2: Slope Stability
!*************************************************************************************!
  FINISH
  ~CFCLEAR,,1
  ~CFACTIV,GETC,Y
  NomFile='CFVR3217'
  /TITLE, %NomFile%, Slope stability with non horizontal reinforced earth

! -------------------------------------------------------------------------------------
! 1. Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,SI

/PREP7
! 2. Materials
! --------------------------------------------------
~CFMP,1,LIB,SOIL,,OH
~CFMP,1,SOIL,GAMD,,20000
~CFMP,1,SOIL,PHIMCEFF,,28
~CFMP,1,SOIL,CMCEFF  ,,0

! 3. Elements
! --------------------------------------------------
ET,1,PLANE42

! 4. MODEL
! --------------------------------------------------
K, 1,  0, 0
K, 2, 25, 0
K, 3, 25,13
K, 4, 16,13
K, 5,  8, 5
K, 6,  0, 5
A,1,2,3,4,5,6
AESIZE,ALL,1.5
MAT,1
AMESH,1
EPLOT
/IMAGE, SAVE, %NomFile%,BMP

! 5. Capturing Model
! --------------------------------------------------
~SLPINK,6,3,5

! 6. Sliding Surface
! --------------------------------------------------
~SLPPOL,11,8
~SLPPOL,21,13

! 7. Reinforcement
! --------------------------------------------------
~REDEF,1,13.5,8.0,13.501,8.0,2,0.30,0,0,-30

! 8. Solve
! --------------------------------------------------
/POST1
~SLPOPT,0.01,20,2,10, ,1
~SLPSOL,2,1,0.0,0.0 ! Janbu

! 9. Data Check
! --------------------------------------------------
! Data comparison number
  NComp    = 1
  NComp_ch = 0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! 10. Labels, Correct data, obtained data
! --------------------------------------------------
  LABEL(1) = 'F'
  ~CFGET,VALUE(  1,2),SLOPE,,RES,F,,1,1
  VALUE(  1,1) =  1.16
! Warning and error tolerances
  TOLER(  1,1) = 0.01  $  TOLER(  1,2) = 0.01

! 11. Results comparison
! --------------------------------------------------
  COMPARA.MAC