!*************************************************************************************!
! TITLE: CFVR4016 - Reinforced concrete design according to GB 50010 Chinese code
! SUBTITLE: Shear force design.
!
! DESCRIPTION: A concrete simply supported beam with rectangular shape section and
! DESCRIPTION: shear reinforcement is subjected to a uniform load.
! DESCRIPTION:
! DESCRIPTION: Determine the area per unit of length of dimensioned shear reinforcement.
! DESCRIPTION: according to GB 50010.
! DESCRIPTION:
!
! ELEMENT TYPE: BEAM3
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Code Checking/Design
! KEYWORD4: Reinforced Concrete
! KEYWORD5: GB 50010
!
!*************************************************************************************!
   FINISH
  ~CFCLEAR,,1
   NomFile='CFVR4016'
 /TITLE, %NomFile%, SHEAR DESIGN ACCORDING TO GB50010

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
 ~UNITS,,LENG,M
 ~UNITS,,TIME,S
 ~UNITS,,FORC,KN
 ~CODESEL,,GB50010

! Preprocessor
  /PREP7

! Parameters
  L=10         ! Length between supports, in m
  b=.3         ! Cross-section width in m.
  h=.5         ! Depth in m.
  Q=85	       ! Uniform distributed load in KN/m

! Material Definition
 ~CFMP,1,LIB,CONCRETE,GB50010,C35
 ~CFMP,2,LIB,REINF,GB50010,HPB235
 ~CFMP,2,GB_S    ,GAMs    ,,1.10

! Element Type Definition
  ET,1,Beam3                            ! Element Type 1: 2D Beam

! Cross-section definition
 ~CSECDMS,1,REC,1,0.5,0.3

! Reinforcement definition
 ~RNFDEF,1,1,2,4,0,0.0,0.6368E-2         ! Bot. reinf. for bending
 ~RNFDEF,1,2,2,2,0,0.0,0.2283E-2,        ! Top reinf. for bending
 ~RNFDEF,1,SHEAR,2,0.0,0.0,1E-4,0.0      ! Shear reinf.
! Beam & Shell property
 ~BMSHPRO,1,BEAM,1,1,,,3,1,0,,Beam property

! Code properties definition
 ~SECMDF,1,GB50010P,REC,,0.05

! Model Construction
  N,1                                   ! Nodes input
  N,21,L
  FILL,1,21

  E,1,2                                 ! Elements input
  EGEN,20,1,1,1

  D,1, , , , , ,UX,UY                   ! Constraint conditions
  D,21, , , , , ,UY

/SOLU
  SFBEAM,ALL,1,PRES,Q
  SOLVE               ! Calculation

/POST1
! Postprocessor
  ~CFSET,,1,1       ! First load step

! Shear in Y design according to GB50010
  ~DIMCON,SHT,SHEAR

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data Comparison number
  NComp = 4
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'VRD1'
  LABEL(2,1) = 'VS'
  LABEL(3,1) = 'VRD2'
  LABEL(4,1) = 'ASSH'

! Correct values
  VALUE(1,1)=0.564E3
  VALUE(2,1)=0.234E3
  VALUE(3,1)=0.149E3
  VALUE(4,1)=0.194E-2

! Comparison
 ~PLLSCON,VRD1
 *GET,VALUE(1,2),ELEM,19,ETAB,CFETAB_J
 ~PLLSCON,VS
 *GET,VALUE(2,2),ELEM,19,ETAB,CFETAB_J
 ~PLLSCON,VRD2
 *GET,VALUE(3,2),ELEM,19,ETAB,CFETAB_J
 ~PLLSCON,ASSH
 *GET,VALUE(4,2),ELEM,19,ETAB,CFETAB_J

! Warning and error tolerances
  TOLER( 1,1)= 1E-0 $ TOLER( 1,2)= 1E-0
  TOLER( 2,1)= 1E-0 $ TOLER( 2,2)= 1E-0
  TOLER( 3,1)= 1E-0 $ TOLER( 3,2)= 1E-0
  TOLER( 4,1)= 1E-3 $ TOLER( 4,2)= 1E-3

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC