!*************************************************************************************!
! TITLE: CFVR4053 - Reinforced concrete design according to GB 50010 2010 Chinese code
! SUBTITLE: Shear design without seismic action.
!
! DESCRIPTION: A concrete simply supported beam with rectangular shape section 
! DESCRIPTION: is subjected to a uniform load and two concentrated loads.
! DESCRIPTION:
! DESCRIPTION: Determine the shear reinforcement according to GB 50010-2010.
!
! ELEMENT TYPE: BEAM3
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Code Checking/Design
! KEYWORD4: Reinforced Concrete
! KEYWORD5: GB 50010
!
!*************************************************************************************!

FINISH
~CFCLEAR,,1

NomFile='CFVR4053'
/TITLE, %NomFile%, Shear design according to GB50010 code (2010 version)

!-------------------------------------------------------------------------------
! initial data
!-------------------------------------------------------------------------------
~UNITS,,LENG,MM 
~UNITS,,FORC,KN  
~CODESEL,,GB50010N

! Parameters
qL=10
Fp=140
L1=1500
L2=L1+1000
L3=L2+L1

/PREP7

! materials
~CFMP,1,LIB,CONCRETE,GB50010,C30
~CFMP,2,LIB,REINF,GB50010,HPB300

! element type
ET,1,BEAM3

! cross-section
~CSECDMS,1,REC,1,600.,250.
~RNFDEF,1,SHEAR,2

! beam properties
~BMSHPRO,1,BEAM,1,1,,,3,1,0
~MEMBPRO,1,GB50010N,ALL,1,1,0.0

K,1,0
K,2,L1
K,3,L2
K,4,L3
L,1,2,(L1/1000)/4
L,2,3,((L2-L1)/1000)/4
L,3,4,(L1/1000)/4
LMESH,ALL

! loads  
DK,1,UX
DK,1,UY
DK,4,UY
FK,2,FY,-Fp
FK,3,FY,-Fp
SFBEAM,ALL,1,PRES,qL/1000  
ALLSEL

! resolution & postprocessing
/SOLU
SOLVE
/POST1
~CFSET,,1
~DIMCON,SHT,SHEAR

!-------------------------------------------------------------------------------
! data check
!-------------------------------------------------------------------------------

! arrays
NComp    = 5
NComp_ch = 0
*DIM,LABEL,CHAR,Ncomp,1
*DIM,LABEL_CH,CHAR,Ncomp_ch,1
*DIM,VALUE,,Ncomp,3
*DIM,VALUE_CH,CHAR,Ncomp_ch,3
*DIM,TOLER,,Ncomp,2

! labels
LABEL(1) = 'VRD1'
LABEL(2) = 'CRVRD1'
LABEL(3) = 'VRD2'
LABEL(4) = 'CRVRD2'
LABEL(5) = 'ASSH'

! correct data
VALUE(1,1) = 500.5
VALUE(2,1) = 160./VALUE(1,1)
VALUE(3,1) = 140.14
VALUE(4,1) = 160./VALUE(3,1)
VALUE(5,1) = 0.13

! CivilFEM data
~PLLSCON,VRD1
*GET,VALUE(1,2),ELEM,1,ETAB,CFETAB_I
~PLLSCON,CRVRD1
*GET,VALUE(2,2),ELEM,1,ETAB,CFETAB_I
~PLLSCON,VRD2
*GET,VALUE(3,2),ELEM,1,ETAB,CFETAB_I
~PLLSCON,CRVRD2
*GET,VALUE(4,2),ELEM,1,ETAB,CFETAB_I
~PLLSCON,ASSH
*GET,VALUE(5,2),ELEM,1,ETAB,CFETAB_I

! results comparison
EREL = 5.E-3
*DO,I,1,NCOMP
  TOLER(I,1) = EREL*ABS(VALUE(I,1))
  TOLER(I,2) = TOLER(I,1)
*ENDDO

COMPARA.MAC