!*************************************************************************************!
! TITLE: CFVR4512 - GB50017: Shear Checking
! SUBTITLE:
!
! DESCRIPTION: A fixed-fixed steel beam is subjected to a surface load of 1000 kN.
! DESCRIPTION:
! DESCRIPTION: The beam has a length of 25 m.
! DESCRIPTION:
! DESCRIPTION: The cross section is an angle one with the following dimensions:
! DESCRIPTION:
! DESCRIPTION: - h = 200 mm
! DESCRIPTION:
! DESCRIPTION: - t = 18 mm
! DESCRIPTION:
! DESCRIPTION: The beam is made of GB 50017 Q420.
! DESCRIPTION:
! DESCRIPTION: The aim of the example is to obtain the shear
! DESCRIPTION: criterion according to GB 50017.
!
! ELEMENT TYPE: BEAM3
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Steel
! KEYWORD4: Code Checking/Design
! KEYWORD5: GB 50017
!
!*************************************************************************************!
  FINISH
  ~CFCLEAR,,1
  NomFile='CFVR4512'
  /TITLE, %NomFile%, GB50017: Shear Checking

! ---------------------------------------------------------------------------------
! Model definition
! ---------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
  ~UNITS,,LENG,M
  ~UNITS,,TIME,S
  ~UNITS,,FORC,KN
  ~CODESEL,GB50017,EC2,,,EC8-94

/PREP7
! Preprocessor
! --------------------------------------------------
! Materials
  ~CFMP,1,LIB,STEEL,GB50017,Q420   ! GB50017  Q420
! Element Types
  ET,1,BEAM3            ! Type 1: 2D Beam
! Cross sections
  ~SSECDMS,1,L,1,200E-3,18E-3,200E-3,18E-3,6.911E-3  ! L Angle dimensions
! Beam Properties
  ~BMSHPRO,1,BEAM,1,1,,,3,1,0,,Beam properties

! Nodes
  N, 1
  N,25,1
  FILL, 1,25
! Elements
  E,1,2
  EGEN,24,1,1
  EPLOT
/SOLU
! Solution
! --------------------------------------------------
! Displacements
  D, 1,ALL
  D,25,ALL
! Apply Load
  SFBEAM,ALL,1,PRES,1000
! Solve
  SOLVE

/POST1
! Postprocessor
! --------------------------------------------------
! Read results
  ~CFSET,,1,1       ! Read first load step
! Shear checking
  ~CHKSTL,SHEAR

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
  NComp    =  2
  NComp_ch =  0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'SEQ'
  LABEL(2,1) = 'CRT_TOT'

! Correct values
  VALUE(1,1) = 101750.1017500810
  VALUE(2,1) = 0.48896

! Obtained values
  ~PLLSSTL,SEQ
  *GET,VALUE(1,2),ELEM,5,ETAB,CFETAB_I
  ~PLLSSTL,CRT_TOT
  *GET,VALUE(2,2),ELEM,5,ETAB,CFETAB_I

! Warning and error tolerances
  TOLER(1,1) = 1E0  $ TOLER(1,2) = 1E+2
  TOLER(2,1) = 1E-5 $ TOLER(2,2) = 1E-4

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC