!*************************************************************************************!
! TITLE: CFVR7054 - Compression checking according to AASHTO 2010
! SUBTITLE: Compression checking of a cantilever steel beam
!
! DESCRIPTION: A steel cantilever beam with L angle shape section is subjected to an
! DESCRIPTION: axial compression force of 30 KN at free end.
! DESCRIPTION:
! DESCRIPTION: Determine the total criterion according to AASHTO 2010.
! DESCRIPTION:
!
! ELEMENT TYPE: BEAM188
! MODULES:
! UNITS: SI
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Code Checking/Design
! KEYWORD4: Steel
! KEYWORD5: AASHTO10
!
!*************************************************************************************!
FINISH
~CFCLEAR,,1
   NomFile='CFVR7054'
 /TITLE, %NomFile%, Compression checking according to AASHTO10

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
~CODESEL,AASHTO10,EC2-91,EC2-91,,EC8-94

/PREP7

ET,1,Beam188,,,2

~CFMP,1,LIB,STEEL,ASTM,A441
~SSECLIB,1,1,57,71   !L 4x4x1/4
~MEMBPRO,1,AASHTO10,ALL,2.000,2.000,2.000,1.000,1.000,0.000,1.000,1.000,0.000,
~BMSHPRO,1,BEAM,1,1,,,188,1,1,,Beam 1

N,1,
N,2,2
E,1,2


EPLOT

D,1,ALL

F,2,FX,-30000

/SOLU
SOLVE

/POST1
~CFSET,0,1,LAST,

~CHKSTL,COMPFBK

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 7
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'QS'
  LABEL(2,1) = 'QA'
  LABEL(3,1) = 'Q'
  LABEL(4,1) = 'PO'
  LABEL(5,1) = 'PE'
  LABEL(6,1) = 'PN'
  LABEL(7,1) = 'CRT_TOT'

! Correct values
  VALUE(1,1)= 0.835
  VALUE(2,1)= 1
  VALUE(3,1)= 0.835
  VALUE(4,1)= 360319.6
  VALUE(5,1)= 62945.9
  VALUE(6,1)= 55203.5
  VALUE(7,1)= 0.60

! Comparison

 ~PLLSSTL,QS
 *GET,VALUE(1,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,QA
 *GET,VALUE(2,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,Q
 *GET,VALUE(3,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,PO
 *GET,VALUE(4,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,PE
 *GET,VALUE(5,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,PN
 *GET,VALUE(6,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,CRT_TOT
 *GET,VALUE(7,2),ELEM,1,ETAB,CFETAB_I


! Warning and error tolerances
  TOLER( 1, 1)= 1E-03   $ TOLER( 1, 2)= 1E-03
  TOLER( 2, 1)= 1E-03   $ TOLER( 2, 2)= 1E-03
  TOLER( 3, 1)= 1E-03   $ TOLER( 3, 2)= 1E-03
  TOLER( 4, 1)= 1E-01   $ TOLER( 4, 2)= 1E-01
  TOLER( 5, 1)= 1E-02   $ TOLER( 5, 2)= 1E-02	
  TOLER( 6, 1)= 1E+00   $ TOLER( 6, 2)= 1E+00	! Rounding error accepted
  TOLER( 7, 1)= 5E-03   $ TOLER( 7, 2)= 5E-03

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC