!******************************************************************************!
! TITLE: CFVR7060 - AASHTO10: Shear Checking of a Box Section
! SUBTITLE: Shear checking according to AASHTO10 Box section.
!
! DESCRIPTION: A cantilever steel beam is subjected to end shears of 11 kips 
! DESCRIPTION: from dead load and 33 kips from live load.
! DESCRIPTION:
! DESCRIPTION: The beam has a length of 100 in.
! DESCRIPTION: 
! DESCRIPTION: Section material properties:
! DESCRIPTION:   A529Gr42 ,  Fy = 46 ksi , Fu = 58 ksi
! DESCRIPTION:
! DESCRIPTION: Geometric properties:
! DESCRIPTION:   TS 6x4x3/8, d = 6.0 in.,  w = 4.0 in., tw = 0.375 in.
! DESCRIPTION 
! DESCRIPTION: The aim of the example is to obtain the shear criterion
! DESCRIPTION: according to AISC-LRFD13.
! DESCRIPTION:
! DESCRIPTION: Reference:
! DESCRIPTION:   AISC, Design Examples, Version 13.0
! DESCRIPTION:   Example G.4, Rectangular HSS in Shear
! DESCRIPTION:
!
! ELEMENT TYPE: BEAM3
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Steel
! KEYWORD4: Code Checking/Design
! KEYWORD5: AASHTO10
!
!*******************************************************************************

FINISH
~CFCLEAR,,1
NomFile='CFVR7060'
/TITLE, %NomFile%, AASHTO10: Shear Checking Box Section

!-------------------------------------------------------------------------------
! Model definition
!-------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
~UNITS,,LENG,IN
~UNITS,,TIME,S
~UNITS,,FORC,KIPS
~CODESEL,AASHTO10,EC2-08,,,EC8-04
   

/PREP7

! Materials
~CFMP,1,LIB,STEEL,ASTM,A529Gr42 
~CFMP,1,USER
~CFMP,1,AASHTO10,Fy,,46 ,1,0,0
~CFMP,1,AASHTO10,Fu,,58 ,1,0,0

! Element Types
ET,1,BEAM3  ! Type 1: 2D Beam

! Cross Section
~SSECLIB,1,1,61,246   !TS 6x4   

! Member Properties
~MEMBPRO,1,AASHTO10,ALL,0.000,1.000,1.000,1.000,1.000,0.000,1.000,1.000,0.000,  


! Beam & Shell Property
~BMSHPRO,1,BEAM,1,1,,,3,1,0,,Beam 1

! Nodes
N,1,0.,0.
N,2,100.,0.

! Elements
E,1,2
  
/SOLU
! Loads
D,1,ALL
F,2,FY,1.2*(11)+1.6*(33)

SOLVE

/POST1
~CFSET,,1,1 
~CHKSTL,SHEAR
!-------------------------------------------------------------------------------------
! DATA CHECK
!-------------------------------------------------------------------------------------
! Data comparison number
NComp = 3
NComp_ch = 0

! Marix dim.
*DIM,LABEL,CHAR,Ncomp,1
*DIM,LABEL_CH,CHAR,Ncomp_ch,1
*DIM,VALUE,,Ncomp,3
*DIM,VALUE_CH,CHAR,Ncomp_ch,3
*DIM,TOLER,,Ncomp,2


! Labels
LABEL(1,1) = 'VN'
LABEL(2,1) = 'AW'
LABEL(3,1) = 'CRT_TOT'

! Correct values
VALUE(1,1) = 75.04
VALUE(2,1) = 2.8125
VALUE(3,1) = 0.88

! Comparison
~PLLSSTL,VN
*GET,VALUE(1,2),ELEM,1,ETAB,CFETAB_J
~PLLSSTL,AW
*GET,VALUE(2,2),ELEM,1,ETAB,CFETAB_J
~PLLSSTL,CRT_TOT
*GET,VALUE(3,2),ELEM,1,ETAB,CFETAB_J

! Warning and error tolerances
TOLER(1,1)= 0.01*VALUE(1,1) $ TOLER(1,2)= 0.01*VALUE(1,1)
TOLER(2,1)= 0.01*VALUE(2,1) $ TOLER(2,2)= 0.01*VALUE(2,1) 
TOLER(3,1)= 0.01*VALUE(3,1) $ TOLER(3,2)= 0.01*VALUE(3,1) 

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC