!***************************************************************************************************!
! TITLE: CFVR7225 - Shear checking according to ACI 349
! SUBTITLE: Check a reinforced concrete beam subjected to shear force according to ACI 349
!
! DESCRIPTION: A beam which is fixed at the right and simply supported at the left,
! DESCRIPTION: has a T reinforced concrete section and it is subjected
! DESCRIPTION: to a uniform distributed load of 30 Mp/m.
! DESCRIPTION:
! DESCRIPTION: The aim of the example is to obtain the check criterion according to ACI 349.
!
! ELEMENT TYPE: BEAM3
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Code Checking/Design
! KEYWORD4: Reinforced Concrete
! KEYWORD5: ACI 349
!
!***************************************************************************************************!
   FINISH
  ~CFCLEAR,,1
   NomFile='CFVR7225'
 /TITLE,%NomFile%, SHEAR CHECKING ACCORDING TO ACI 349

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
~CFACTIV,NUCL,Y
~UNITS,,LENG,M
~UNITS,,TIME,S
~UNITS,,FORC,MP
~CODESEL,EC3-92,ACI349,,,EC8-94

! Preprocessor
  /PREP7

! Parameters
  L=20         ! Length between supports, in m
  Q=20*1.5     ! Uniform distributed load in Mp/m

! Material Definition
 ~CFMP,3,LIB,CONCRETE,ACI,fc_3500
 ~CFMP,4,LIB,REINF,ACI,fy_70000

! Element Type Definition
  ET,1,Beam3                            ! Element Type 1: 2D Beam

! Cross-section definition
 ~CSECDMS,2,T,3,0.7,0.2,0.4,0.2
! Reinforcement definition
 ~RNFDEF,2,SHEAR,4,,,.00228             ! Shear reinf.
! Code properties definition
  ~SECMDF,2,ACI349PR,REC,,5e-002
! Beam properties
  ~BMSHPRO,1,BEAM,2,2,,,3,,,,Beam properties

! Model Construction
  MAT,3
  N,1                                   ! Nodes input
  N,21,L
  FILL,1,21

  E,1,2                                 ! Elements input
  EGEN,20,1,1,1

  D,1, , , , , ,UX,UY                   ! Boundary conditions
  D,21, , , , , ,UY

/SOLU
  SFBEAM,ALL,1,PRES,Q
  SOLVE               ! Calculation

/POST1

! Postprocessor
  ~CFSET,,1,1       ! Read first load step

! Shear in Y checking according to ACI 349
  ~CHKCON,SHT,SHEAR,0, , ,1
!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 6
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'VC'
  LABEL(2,1) = 'VS'
  LABEL(3,1) = 'VN'
  LABEL(4,1) = 'VFI'
  LABEL(5,1) = 'CRTVN'
  LABEL(6,1) = 'CRT_TOT'

! Correct values
  VALUE(1,1)=10.83
  VALUE(2,1)=43.32
  VALUE(3,1)=54.15
  VALUE(4,1)=46.03
  VALUE(5,1)=5.54
  VALUE(6,1)=6.52

! Comparison
 ~PLLSCON,VC
 *GET,VALUE(1,2),ELEM,20,ETAB,CFETAB_J
 ~PLLSCON,VS
  *GET,VALUE(2,2),ELEM,20,ETAB,CFETAB_J
 ~PLLSCON,VN
  *GET,VALUE(3,2),ELEM,20,ETAB,CFETAB_J
 ~PLLSCON,VFI
  *GET,VALUE(4,2),ELEM,20,ETAB,CFETAB_J
 ~PLLSCON,CRTVN
  *GET,VALUE(5,2),ELEM,20,ETAB,CFETAB_J
 ~PLLSCON,CRT_TOT
  *GET,VALUE(6,2),ELEM,20,ETAB,CFETAB_J

! Warning and error tolerances
  TOLER( 1, 1)= 1E-01 $ TOLER( 1, 2)= 1E-01
  TOLER( 2, 1)= 1E-01 $ TOLER( 2, 2)= 1E-01
  TOLER( 3, 1)= 1E0   $ TOLER( 3, 2)= 1E0
  TOLER( 4, 1)= 1E-01 $ TOLER( 4, 2)= 1E-01
  TOLER( 5, 1)= 1E-01 $ TOLER( 5, 2)= 1E-01
  TOLER( 6, 1)= 1E-01 $ TOLER( 6, 2)= 1E-01
!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC