!********************************************************************************************!
! TITLE: CFVR7229 - Bending + Axial force checking according to ACI 349
! SUBTITLE: Check a concrete beam subjected to Bending + Axial force according to ACI 349
!
! DESCRIPTION: A fixed beam which has a rectangular concrete section is subjected to
! DESCRIPTION: an axial compression force of 700000 lbf and a bending moment of 1200000 ft-lbf.
! DESCRIPTION:
! DESCRIPTION: The aim of the example is to obtain the check criterion according to ACI 349.
!
! ELEMENT TYPE: BEAM188
! MODULES:
! UNITS: BFT
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Code Checking/Design
! KEYWORD4: Reinforced Concrete
! KEYWORD5: ACI 349
!
!********************************************************************************************!
FINISH
~CFCLEAR,,1
  NomFile='CFVR7229'
 /TITLE,%NomFile%, BENDING + AXIAL FORCE CHECKING ACCORDING TO ACI 349

! --------------------------------------------------------------------
! Initial data
! --------------------------------------------------------------------
! CivilFEM SETUP
~CODESEL,,ACI349
~UNITS,BFT

! Parameters
Phi=35.796
H=-700000  ! compression force
M=1200000  ! bending moment
         
! Preprocessor
/PREP7  

! Material definition:Concrete and steel 
~CFMP,1,LIB,CONCRETE,ACI,fc_5000
~CFMP,1,ACI_C,TSDSSD,,2  
~CFMP,1,USER
~CFMP,1,ACI_C,Ec,,5.80464e+008,7  
~CFMP,2,LIB,REINF,ACI,fy_60000

! Cross-section definition
~CSECDMS,1,REC,1,3,3
*DO,II,1,3
~TREFINE,1  
*ENDDO
~RNFDEF,1,2,2,2,0,0.25, , ,Phi,2, , ,3
~RNFDEF,1,4,2,4,0,0.25, , ,Phi,2, , ,3
~RNFDEF,1,1,2,1,0,0.25, , ,Phi,4, , ,4
~RNFDEF,1,3,2,3,0,0.25, , ,Phi,4, , ,4
                
! Beam & Shell property
~BMSHPRO,1,BEAM,1,1,,, 188,1,0,,Beam property  

! Element type definition
ET,1,BEAM188  ! Element Type 1: 2D Beam
SECNUM,1

! Model construction
N,1
N,2,1
E,1,2
D,1,ALL

/SOLU

F,2,MZ,M   
F,2,FX,H   
SOLVE      ! Calculation

/POST1
~CFSET,,1  ! Read first load step

! Bending + Axial checking for rectangular sections according to ACI
 ~CHKCON,2DB,,0

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 2
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'CRTC2D_I'
  LABEL(2,1) = 'CRTC2D_J'

! Correct values
  VALUE(1,1)=0.75
  VALUE(2,1)=0.75

! Comparison
 ~PLLSCON,CRT_TOT
 *GET,VALUE(1,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,CRT_TOT
 *GET,VALUE(2,2),ELEM,1,ETAB,CFETAB_J

! Warning and error tolerances
  TOLER( 1, 1)= 1E-01 $ TOLER( 1, 2)= 1E-01
  TOLER( 2, 1)= 1E-01 $ TOLER( 2, 2)= 1E-01

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC