!*************************************************************************************!
! TITLE: CFVR7280 - Shear checking according to ACI 349 13
! SUBTITLE: Check a reinforced concrete beam subjected to shear force according to ACI 349 13
!
! DESCRIPTION: A beam which is fixed at the right and simply supported at the left,
! DESCRIPTION: has a rectangular reinforced concrete section
! DESCRIPTION: and it is subjected to a uniform distributed load of 6.75 Mp/m.
! DESCRIPTION:
! DESCRIPTION: The aim of the example is to obtain the check criterion according to ACI 349 13.
!
! ELEMENT TYPE: BEAM3
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Code Checking/Design
! KEYWORD4: Reinforced Concrete
! KEYWORD5: ACI 349 13
!
!*************************************************************************************!
   FINISH
  ~CFCLEAR,,1
   NomFile='CFVR7280'
 /TITLE,%NomFile%, SHEAR CHECKING ACCORDING TO ACI 349 13

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
~UNITS,,LENG,M
~UNITS,,TIME,S
~UNITS,,FORC,MP
~CODESEL,EC3-05,ACI34913,EC2-08,,EC8-04 

! Preprocessor
  /PREP7

! Parameters
  L=10         ! Length between supports, in m
  b=.3         ! Cross-section width in m.
  h=.5         ! Depth in m.
  Q=4.5*1.5    ! Uniform distributed load in Mp/m

! Material Definition
 ~CFMP,3,LIB,CONCRETE,ACI,fc_4500
 ~CFMP,4,LIB,REINF,ACI,fy_60000
 ~CFMP,3,ACI_14_C,Lambda  ,,0.8  
 
! Element Type Definition
  ET,1,Beam3                            ! Element Type 1: 2D Beam

! Cross-section definition
 ~CSECDMS,2,REC,3,0.5,0.3
 
! Reinforcement definition
 ~RNFDEF,2,1,4,4,,,0.6368E-02     ! Bot. reinf. for bending
 ~RNFMDF,2,1,GC,50.000E-03   
 ~RNFDEF,2,2,4,2,,,0.2283E-02     ! Top reinf. for bending
 ~RNFMDF,2,2,GC,50.000E-03   
 ~RNFDEF,2,SHEAR,4,,,.00128       ! Shear reinf.
 
! Code properties definition
  ~SECMDF,2,ACI349PR,REC,,5e-02,0,0,0
  
! Beam and Shell properties
  ~BMSHPRO,1,BEAM,2,2,,,3,,,,Beam property

! Model Construction
  MAT,3
  N,1                                   ! Nodes input
  N,21,L
  FILL,1,21
  E,1,2                                 ! Elements input
  EGEN,20,1,1,1
  D,1, , , , , ,UX,UY                   ! Boundary conditions
  D,21,UY

/SOLU
  SFBEAM,ALL,1,PRES,Q
  SOLVE               ! Calculation

/POST1

! Postprocessor
  ~CFSET,,1,1       ! Read first load step

! Shear in Y checking according to ACI
~CHKCON,SHT,SHEAR,0, , ,1, , , , , ,0 

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 6
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'VC'
  LABEL(2,1) = 'VS'
  LABEL(3,1) = 'VN'
  LABEL(4,1) = 'VFI'
  LABEL(5,1) = 'CRTVN'
  LABEL(6,1) = 'CRT_TOT'

! Correct values
  VALUE(1,1)=10.20
  VALUE(2,1)=24.29
  VALUE(3,1)=10.20+24.29
  VALUE(4,1)=(10.20+24.29)*0.75
  VALUE(5,1)=33.75/(10.20+24.29)
  VALUE(6,1)=33.75/((10.20+24.29)*0.75)

! Comparison 
 ~CFGET,VALUE( 1,2),ELEMENT,20,RESULT,VC,J
 ~CFGET,VALUE( 2,2),ELEMENT,20,RESULT,VS,J
 ~CFGET,VALUE( 3,2),ELEMENT,20,RESULT,VN,J
 ~CFGET,VALUE( 4,2),ELEMENT,20,RESULT,VFI,J
 ~CFGET,VALUE( 5,2),ELEMENT,20,RESULT,CRTVN,J
 ~CFGET,VALUE( 6,2),ELEMENT,20,RESULT,CRT_TOT,J

! Warning and error tolerances  
  TOLER(1,1)= 0.01*VALUE(1,1) $ TOLER(1,2)= 0.01*VALUE(1,1)
  TOLER(2,1)= 0.01*VALUE(2,1) $ TOLER(2,2)= 0.01*VALUE(2,1) 
  TOLER(3,1)= 0.01*VALUE(3,1) $ TOLER(3,2)= 0.01*VALUE(3,1) 
  TOLER(4,1)= 0.01*VALUE(4,1) $ TOLER(4,2)= 0.01*VALUE(4,1) 
  TOLER(5,1)= 0.01*VALUE(5,1) $ TOLER(5,2)= 0.01*VALUE(5,1) 
  TOLER(6,1)= 0.01*VALUE(6,1) $ TOLER(6,2)= 0.01*VALUE(6,1) 

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC