!*************************************************************************************!
! TITLE: CFVR7314 - Steel checking according to ASME BPVC III Subsection NF
! SUBTITLE: Compression checking of a cantilever steel beam
!
! DESCRIPTION: A steel cantilever beam with L angular shape section is subjected to
! DESCRIPTION: a horizontal compression force of 1 MN at free end.
! DESCRIPTION: Ct reduction coefficient is taken as 0.85
! DESCRIPTION:
! DESCRIPTION: Determine the total criterion according to ASME BPVC III Subsection NF.
! DESCRIPTION:
!
! ELEMENT TYPE: BEAM188
! MODULES:
! UNITS: SI
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Code Checking/Design
! KEYWORD4: Steel
! KEYWORD5: ASME BPVC III NF
!
!*************************************************************************************!

FINISH
~CFCLEAR,,1

   NomFile='CFVR7314'
 /TITLE, %NomFile%, Compression checking ASME BPVC III subsection NF
! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
~CFACTIV,NUCL,Y
~CODESEL,ASME_NF,EC2-91,EC2-91,,EC8-94

/PREP7

ET,1,Beam188,,,2

~CFMP,1,LIB,STEEL,ASTM,A441
~CFMP,1,USER
~CFMP,1,STEEL,STYPE,,1  ! Austenitic
~SSECLIB,1,1,57,33   !L 6x6x7/16
~SECMDF,1,ASMENFPR,CT,,0.85
~MEMBPRO,1,ASME_NF,ALL,3.0,2.0,2.0,1.0,1.0,1.0,1.0,0,1,0
~BMSHPRO,1,BEAM,1,1,,,188,1,1,,Beam 1

N,1,0
N,2,3
E,1,2

/SHRINK,0
/ESHAPE,1.0

EPLOT

D,1,ALL

F,2,FX,-1E6

/SOLU
SOLVE

/POST1
~CFSET,0,1,LAST

~CHKSTL,COMPRESS

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 6
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'QS'
  LABEL(2,1) = 'FA'
  LABEL(3,1) = 'CRT_STR'
  LABEL(4,1) = 'SLD_RT'
  LABEL(5,1) = 'CRT_SLD'
  LABEL(6,1) = 'CRT_TOT'

! Correct values
  VALUE(1,1)=0.906
  VALUE(2,1)=65315757
  VALUE(3,1)=4.689
  VALUE(4,1)=126.321
  VALUE(5,1)=0.632
  VALUE(6,1)=4.689

! Comparison
 ~PLLSSTL,QS
 *GET,VALUE(1,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,FA
 *GET,VALUE(2,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,CRT_STR
 *GET,VALUE(3,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,SLD_RT
 *GET,VALUE(4,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,CRT_SLD
 *GET,VALUE(5,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,CRT_TOT
 *GET,VALUE(6,2),ELEM,1,ETAB,CFETAB_I

! Warning and error tolerances
  TOLER( 1, 1)= 1E-02   $ TOLER( 1, 2)= 1E-02
  TOLER( 2, 1)= 1E+02   $ TOLER( 2, 2)= 1E+02	! Rounding error accepted
  TOLER( 3, 1)= 1E-03   $ TOLER( 3, 2)= 1E-03
  TOLER( 4, 1)= 1E-03   $ TOLER( 4, 2)= 1E-03	
  TOLER( 5, 1)= 1E-03   $ TOLER( 5, 2)= 1E-03
  TOLER( 6, 1)= 1E-03   $ TOLER( 6, 2)= 1E-03


!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC