!******************************************************************************!
! TITLE: CFVR7706 - AISC-ASD13: Flexure Checking of an I Section, Strong Axis
! SUBTITLE: Flexure checking according to AISC-ASD13 of an I-shape section 
! SUBTITLE: in the strong axis.
!
! DESCRIPTION: A steel beam is subjected to auniform load of 1.74 k/ft.
! DESCRIPTION:
! DESCRIPTION: The beam has a length of 35 ft.
! DESCRIPTION: 
! DESCRIPTION: Section material properties:
! DESCRIPTION:   A529Gr50  ,  Fy = 50 ksi or 7200 ksf , Fu = 65 ksi or 9360 ksf
! DESCRIPTION:
! DESCRIPTION: Geometric properties:
! DESCRIPTION:   W 18x50, Zx = 101 in.^3 or 0.058449 ft^3
! DESCRIPTION 
! DESCRIPTION: The aim of the example is to obtain the flexure criterion
! DESCRIPTION: according to AISC-ASD13.
! DESCRIPTION:
! DESCRIPTION: Reference:
! DESCRIPTION:   AISC, Design Examples, Version 13.0
! DESCRIPTION:   Example F.1-1a, W Shape Flexural Member Design in
! DESCRIPTION:   Strong Axis Bending, Continuously Braced
! DESCRIPTION:  
!
! ELEMENT TYPE: BEAM3
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Steel
! KEYWORD4: Code Checking/Design
! KEYWORD5: ASD 13
!
!*******************************************************************************

FINISH
~CFCLEAR,,1
NomFile='CFVR7706'
/TITLE, %NomFile%, AISC-ASD13: Flexure Checking of I section Strong Axis

!-------------------------------------------------------------------------------
! Model definition
!-------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
~UNITS,,LENG,FT
~UNITS,,TIME,S
~UNITS,,FORC,KIPS
~UNITS,,PRES,,0 ,ksf
~CODESEL,ASD13
   

/PREP7

! Materials
~CFMP,1,LIB,STEEL,ASTM,A529Gr50 
~CFMP,1,USER
~CFMP,1,ASD13  ,Fu      ,,65 ,1,0,0


! Element Types
ET,1,BEAM3  ! Type 1: 2D Beam

! Cross Section
~SSECLIB,1,1,51,148   !W 18x50  

!Member Properties
~MEMBPRO,1,ASD13,ALL,35.00,1.000,1.000,1.000,1.000,0.000,  

! Beam & Shell Property
~BMSHPRO,1,BEAM,1,1,,,3,1,0,,Beam 1

! Nodes
N,1,0.,0.
N,2,17.5,0.
N,3,35.,0.

! Elements
E,1,2
E,2,3
  
/SOLU
! Loads
D,1, , , , , ,UX,UY, , , ,   
D,3, , , , , , ,UY, , , ,
SFBEAM,1,1,PRES,1.2, , , , , ,0 
SFBEAM,2,1,PRES,1.2, , , , , ,0 


SOLVE

/POST1
~CFSET,,1,1 
~CHKSTL,BENDING   
!-------------------------------------------------------------------------------------
! DATA CHECK
!-------------------------------------------------------------------------------------
! Data comparison number
NComp = 3
NComp_ch = 0

! Marix dim.
*DIM,LABEL,CHAR,Ncomp,1
*DIM,LABEL_CH,CHAR,Ncomp_ch,1
*DIM,VALUE,,Ncomp,3
*DIM,VALUE_CH,CHAR,Ncomp_ch,3
*DIM,TOLER,,Ncomp,2


! Labels
LABEL(1,1) = 'CHK_YLD'
LABEL(2,1) = 'MP'
LABEL(3,1) = 'CRT_YLD'

! Correct values
VALUE(1,1) = 1
VALUE(2,1) = 421
VALUE(3,1) = 184/((421)/1.67)

! Comparison
~PLLSSTL,CHK_YLD
*GET,VALUE(1,2),ELEM,1,ETAB,CFETAB_J
~PLLSSTL,MP
*GET,VALUE(2,2),ELEM,1,ETAB,CFETAB_J
~PLLSSTL,CRT_YLD
*GET,VALUE(3,2),ELEM,1,ETAB,CFETAB_J

! Warning and error tolerances
TOLER(1,1)= 0.01*VALUE(1,1) $ TOLER(1,2)= 0.01*VALUE(1,1)
TOLER(2,1)= 0.01*VALUE(2,1) $ TOLER(2,2)= 0.01*VALUE(2,1) 
TOLER(3,1)= 0.01*VALUE(3,1) $ TOLER(3,2)= 0.01*VALUE(3,1) 

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC