!******************************************************************************!
! TITLE: CFVR7712 - AISC-ASD13: Flexure Checking of an I Section, Weak Axis
! SUBTITLE: Flexure checking according to AISC-ASD13 of an I-shape section 
! SUBTITLE: in the weak axis.
!
! DESCRIPTION: A steel beam is subjected to a uniform load of 0.2225 k/in.
! DESCRIPTION: 
! DESCRIPTION:
! DESCRIPTION: The beam has a length of 180 ft.
! DESCRIPTION: 
! DESCRIPTION: Section material properties:
! DESCRIPTION:   A529Gr50  ,  Fy = 50 ksf , Fu = 65 ksi 
! DESCRIPTION:
! DESCRIPTION: Geometric properties:
! DESCRIPTION:   W 12x58, Sy = 24.1 in^3 Zx = 32.5 in.^3 Ix = 107 in^4
! DESCRIPTION 
! DESCRIPTION: The aim of the example is to obtain the shear criterion
! DESCRIPTION: according to AISC-ASD13.
! DESCRIPTION:
! DESCRIPTION: Reference:
! DESCRIPTION:   AISC, Design Examples, Version 13.0
! DESCRIPTION:   Example F.5, I Shaped Flexural Member in Minor-Axis Bending
! DESCRIPTION:   
! DESCRIPTION:  
!
! ELEMENT TYPE: BEAM3
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Steel
! KEYWORD4: Code Checking/Design
! KEYWORD5: ASD 13
!
!*******************************************************************************

FINISH
~CFCLEAR,,1
NomFile='CFVR7712'
/TITLE, %NomFile%, AISC-ASD13: Flexure Checking of I Section Weak Axis

!-------------------------------------------------------------------------------
! Model definition
!-------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
~UNITS,,LENG,in
~UNITS,,TIME,S
~UNITS,,FORC,KIPS
~UNITS,,PRES,,0 ,ksi
~CODESEL,ASD13
   

/PREP7

! Materials
~CFMP,1,LIB,STEEL,ASTM,A529Gr50 
~CFMP,1,USER
~CFMP,1,ASD13  ,Fu      ,,65 ,1,0,0


! Element Types
ET,1,BEAM44  ! Type 1: 2D Beam

! Cross Section
~SSECLIB,1,1,51,217   !W 12x58  

!Member Properties
~MEMBPRO,1,ASD13,ALL,180.0,1.000,1.000,1.000,1.000,0.000,  


! Beam & Shell Property
~BMSHPRO,1,BEAM,1,1,,,44,1,0,,Beam 1

! Nodes
N,1,0.,0.
N,2,90,0.
N,3,180.,0.

! Elements
E,1,2
E,2,3

/SOLU
! Loads
D,1, , , , , ,UX,UY,UZ,ROTX  , ,   
D,3, , , , , , ,UY,UZ, , ,
SFBEAM,1,1,PRES,0.2225, , , , , ,0
SFBEAM,2,1,PRES,0.2225, , , , , ,0

SOLVE

/POST1
~CFSET,,1,1 
~CHKSTL,BENDING,1   

!-------------------------------------------------------------------------------------
! DATA CHECK
!-------------------------------------------------------------------------------------
! Data comparison number
NComp = 3
NComp_ch = 0

! Marix dim.
*DIM,LABEL,CHAR,Ncomp,1
*DIM,LABEL_CH,CHAR,Ncomp_ch,1
*DIM,VALUE,,Ncomp,3
*DIM,VALUE_CH,CHAR,Ncomp_ch,3
*DIM,TOLER,,Ncomp,2


! Labels
LABEL(1,1) = 'CHK_YLD'
LABEL(2,1) = 'MP'
LABEL(3,1) = 'CRT_TOT'

! Correct values
VALUE(1,1) = 1
VALUE(2,1) = 1630
VALUE(3,1) = 900/((1630)/1.67)

! Comparison
~PLLSSTL,CHK_YLD
*GET,VALUE(1,2),ELEM,1,ETAB,CFETAB_J
~PLLSSTL,MP
*GET,VALUE(2,2),ELEM,1,ETAB,CFETAB_J
~PLLSSTL,CRT_TOT
*GET,VALUE(3,2),ELEM,1,ETAB,CFETAB_J

! Warning and error tolerances
TOLER(1,1)= 0.01*VALUE(1,1) $ TOLER(1,2)= 0.01*VALUE(1,1)
TOLER(2,1)= 0.01*VALUE(2,1) $ TOLER(2,2)= 0.01*VALUE(2,1) 
TOLER(3,1)= 0.01*VALUE(3,1) $ TOLER(3,2)= 0.01*VALUE(3,1) 

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC