!*************************************************************************************!
! TITLE: CFVR8660 - AISC15: Chapter E Design of Members for Compression.
! SUBTITLE: Compression check according to AISC/ASD15 - PIPE COMPRESSION MEMBER    
!
! DESCRIPTION: An ASTM A53 Grade B Pipe compression member  with a length of 30ft
! DESCRIPTION: is subjected to axial compression
! DESCRIPTION:
! DESCRIPTION: The aim of the example is to obtain the compression criterion
! DESCRIPTION: according to AISC15 (LRFD/ASD).
! DESCRIPTION: REFERENCE: Volume 1: Design Examples Version 15.1  
! DESCRIPTION: EXAMPLE E.11  PIPE COMPRESSION MEMBER    
!
! ELEMENT TYPE: BEAM188
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Steel
! KEYWORD4: Code Checking/Design
! KEYWORD5: AISC15
!
!*************************************************************************************!
 FINISH
 ~CFCLEAR,,1
 NomFile='CFVR8660'
 /TITLE, %NomFile%, AISC15: Compression Check 
!--------------------------------------------------------------------------------------
! Model definition
!--------------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
  ~UNITS,,LENG,IN
  ~UNITS,,TIME,S
  ~UNITS,,FORC,KIPS! in, sec, Kips
  ~CODESEL,AISC15

! Parameters
  P  = -210        ! Axial force kips
  Fyy = 35         ! ksi
  Fuu = 60         ! ksi

/PREP7
! Preprocessor
! --------------------------------------------------
! Materials
 ~CFMP,1,LIB,STEEL,ASTM,A36 
! ASTM A53 Grade B 
 ~CFMP,1,NAME,,,ASTM A53 Grade B 
 ~CFMP,1,USER
 ~CFMP,1,AISC15  ,Fy,,Fyy ,1,0,0
 ~CFMP,1,AISC15  ,Fu,,Fuu ,1,0,0
 
! Element Types
  ET,1,188  ! Type 1: 3D Beam
  
! Cross Section Standard Pipe
  ~SSECDMS,1,PIPE,1,10.75,0.365,0 ,0 ,,0   
  ~SECMDF,1,NAME,,, 10-in. Standard Pipe

! member property: pinned-pinned condition, effective length = 30 ft*0.80
  ~MEMBPRO,1,AISC15,ALL,30.00*12,1.00,1.00,1.000,1.000,30.00*12,  
   
! Beam & Shell Property
  ~BMSHPRO,1,BEAM,1,1,,,188,1,0,,Beam 1

! Area Update 10-in. Standard Pipe
 ~SECMDF,1,MECHPROP,A        ,,11.5,2,0,0
 ~SECMDF,1,UPDATE
 ~UPDATE,BMSHPRO 
  
! Nodes
  N,1
  N,2,,2
  
! Elements
  SECNUM,1
  REAL,1
  E,1,2  

  /SOLU
! Solution
! --------------------------------------------------
! Constrains
  D,1,ALL
  
! Apply Load
  F,2,FY,P
  
! Solve
  SOLVE
  
  /POST1
! Postprocessor
! --------------------------------------------------
! Read results
  ~CFSET,,1                ! First load case
  
! Checking
 ~CHKSTL,COMPRESS,Z,LRFD   
 ~CHKSTL,COMPRESS,Z,ASD 
 
 !--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 6
  NComp_ch = 0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'FCR'
  LABEL(2,1) = 'PN'
  LABEL(3,1) = 'FE'
  LABEL(4,1) = 'CLS_COMP'
  LABEL(5,1) = 'CRT_LRFD'
  LABEL(6,1) = 'CRT_ASD'

! Correct values
  VALUE(1,1)=21.4         ! Flexural buckling stress (Spec. Eq. E3-2) 
  VALUE(2,1)=246    ! Nominal Compressive Strength (Spec. Eq. E3-1)  
  VALUE(3,1)=29.9          ! Elastic  critical  buckling  stress (Spec. Eq. E3-4)  
  VALUE(4,1)=1.00         ! the pipe is not slender 
  VALUE(5,1)=0.95    ! LRFD CRITERION   210/(0.90*246)
  VALUE(6,1)=1.43    ! ASD CRITERION    210/(246/1.67)

! Comparison

~CFSET,1   ! LRFD 
 ~CFGET,VALUE(1,2),ELEMENT,1,RESULT,FCR,I 
 ~CFGET,VALUE(2,2),ELEMENT,1,RESULT,PN,I 
 ~CFGET,VALUE(3,2),ELEMENT,1,RESULT,FE,I 
 ~CFGET,VALUE(4,2),ELEMENT,1,RESULT,CLS_COMP,I
 ~CFGET,VALUE(5,2),ELEMENT,1,RESULT,CRT_TOT,I
 
~CFSET,2  ! ASD 
 ~CFGET,VALUE(6,2),ELEMENT,1,RESULT,CRT_TOT,I

! Warning and error tolerances
*DO,JJ,1,6
 TOLER(JJ,1)= 0.04*VALUE(JJ,1) $ TOLER(JJ,2)= 0.04*VALUE(JJ,1)
*ENDDO
  
!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC