!*************************************************************************************!
! TITLE: CFVR8677 - AISC15: Chapter G Design of Members for Shear 
! SUBTITLE: Shear check according to AISC15 - RECTANGULAR HSS IN SHEAR    
!
! DESCRIPTION: A rectangular HSS beam is subjected to a shear force.
! DESCRIPTION:
! DESCRIPTION: The beam is ASTM A500 Grade C material.
! DESCRIPTION:
! DESCRIPTION: The aim of the example is to obtain the Available Shear Strength 
! DESCRIPTION: according to AISC15 (LRFD/ASD).
! DESCRIPTION: REFERENCE: Volume 1: Design Examples Version 15.1  
! DESCRIPTION: EXAMPLE G.4 RECTANGULAR HSS IN SHEAR 
!
! ELEMENT TYPE: BEAM188
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Steel
! KEYWORD4: Code Checking/Design
! KEYWORD5: AISC15
!
!*************************************************************************************!
 FINISH
 ~CFCLEAR,,1
 NomFile='CFVR8677'
 /TITLE, %NomFile%, AISC15: Shear Check 
!--------------------------------------------------------------------------------------
! Model definition
!--------------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
  ~UNITS,,LENG,IN
  ~UNITS,,FORC,KIPS! in, Kips
  ~CODESEL,AISC15

! Parameters
  F  = 66		  ! Force kips
  Fyy = 50        ! ksi
  Fuu = 62        ! ksi

/PREP7
! Preprocessor
! --------------------------------------------------
! Materials
 ~CFMP,1,LIB,STEEL,ASTM,A36 
!  ASTM A500 Grade C 
 ~CFMP,1,NAME,,,ASTM A500 Grade C 
 ~CFMP,1,USER
 ~CFMP,1,AISC15  ,Fy,,Fyy ,1,0,0
 ~CFMP,1,AISC15  ,Fu,,Fuu ,1,0,0
 
 
! Element Types
  ET,1,188  ! Type 1: 3D Beam
  
! Cross Section
 ~SSECLIB,1,1,61,246   !TS 6x4  

! Beam & Shell Property
  ~BMSHPRO,1,BEAM,1,1,,,188,1,0,,Beam 1
  
! Nodes
  N,1
  N,2,2
  
! Elements
  SECNUM,1
  REAL,1
  E,1,2  

  /SOLU
! Solution
! --------------------------------------------------
! Constrains
  D,1,ALL
  
! Apply Load
  F,2,FY,F
  
! Solve
  SOLVE
  
  /POST1
! Postprocessor
! --------------------------------------------------
! Read results
  ~CFSET,,1                ! First load case
  
! Checking
  ~CHKSTL,SHEAR,Z,LRFD  
  ~CHKSTL,SHEAR,Z,ASD  
 
 !--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 4
  NComp_ch = 0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'AW'
  LABEL(2,1) = 'VN'
  LABEL(3,1) = 'CRT_LRFD'
  LABEL(4,1) = 'CRT_ASD'

! Correct values
  VALUE(1,1)=3.46              ! Web area
  VALUE(2,1)=104           ! Nominal shear strength
  VALUE(3,1)=0.705            ! Total criterion LRFD
  VALUE(4,1)=1.059            ! Total criterion ASD

! Comparison

~CFSET,1   ! LRFD 
 ~CFGET,VALUE(1,2),ELEMENT,1,RESULT,AW,I 
 ~CFGET,VALUE(2,2),ELEMENT,1,RESULT,VN,I 
 ~CFGET,VALUE(3,2),ELEMENT,1,RESULT,CRT_TOT,I  
 
~CFSET,2  ! ASD 
 ~CFGET,VALUE(4,2),ELEMENT,1,RESULT,CRT_TOT,I

! Warning and error tolerances
*DO,JJ,1,4
 TOLER(JJ,1)= 0.04*VALUE(JJ,1) $ TOLER(JJ,2)= 0.04*VALUE(JJ,1)
*ENDDO
  
!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC