!******************************************************************************!
! TITLE: CFVR8704 - AISC-LRFD14: Shear Checking of a W-shape Section
! SUBTITLE: Shear checking according to AISC LRFD14 W-shape cross section.
!
! DESCRIPTION: A cantilever steel beam is subjected to end shears of 48 kips 
! DESCRIPTION: from dead load and 145 kips from live load.
! DESCRIPTION:
! DESCRIPTION: The beam has a length of 100 in.
! DESCRIPTION: 
! DESCRIPTION: Section material properties:
! DESCRIPTION:   ASTM A572 Gr50,  Fy = 50 ksi , Fu = 65 ksi
! DESCRIPTION:
! DESCRIPTION: Geometric properties:
! DESCRIPTION:   W24x62, d = 23.7 in.,  tw = 0.430 in.
! DESCRIPTION 
! DESCRIPTION: The aim of the example is to obtain the shear criterion
! DESCRIPTION: according to AISC LRFD14.
! DESCRIPTION:
! DESCRIPTION: Reference:
! DESCRIPTION:   AISC, Design Examples, Version 13.0
! DESCRIPTION:   Example G.1a, W-Shape in Strong-Axis Shear
! DESCRIPTION:
!
! ELEMENT TYPE: BEAM3
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Steel
! KEYWORD4: Code Checking/Design
! KEYWORD5: AISC14
!
!*******************************************************************************

FINISH
~CFCLEAR,,1
NomFile='CFVR8704'
/TITLE, %NomFile%, AISC LRFD14: Shear checking W-Shape section

!-------------------------------------------------------------------------------
! Model definition
!-------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
~UNITS,,LENG,IN
~UNITS,,TIME,S
~UNITS,,FORC,KIPS
~UNITS,,PRES,,0 ,ksi
~CODESEL,AISC14
   

/PREP7

! Materials
~CFMP,1,LIB,STEEL,ASTM,A572Gr50

! Element Types
ET,1,BEAM3  ! Type 1: 2D Beam

! Cross Section
~SSECLIB,1,1,51,111  !W 24x62

! Beam & Shell Property
~BMSHPRO,1,BEAM,1,1,,,3,1,0,,Beam 1

! Nodes
N,1,0.,0.
N,2,100.,0.

! Elements
E,1,2
  
/SOLU
! Loads
D,1,ALL
F,2,FY,48. + 145.

SOLVE

/POST1
~CFSET,,1,1 
~CHKSTL,SHEAR,Z,LRFD

!-------------------------------------------------------------------------------------
! DATA CHECK
!-------------------------------------------------------------------------------------
! Data comparison number
NComp = 3
NComp_ch = 0

! Marix dim.
*DIM,LABEL,CHAR,Ncomp,1
*DIM,LABEL_CH,CHAR,Ncomp_ch,1
*DIM,VALUE,,Ncomp,3
*DIM,VALUE_CH,CHAR,Ncomp_ch,3
*DIM,TOLER,,Ncomp,2


! Labels
LABEL(1,1) = 'VN'
LABEL(2,1) = 'AW'
LABEL(3,1) = 'CRT_TOT'

! Correct values
VALUE(1,1) = 306.
VALUE(2,1) = 10.19
VALUE(3,1) = 193./306.

! Comparison
~PLLSSTL,VN
*GET,VALUE(1,2),ELEM,1,ETAB,CFETAB_J
~PLLSSTL,AW
*GET,VALUE(2,2),ELEM,1,ETAB,CFETAB_J
~PLLSSTL,CRT_TOT
*GET,VALUE(3,2),ELEM,1,ETAB,CFETAB_J

! Warning and error tolerances
TOLER(1,1)= 0.01*VALUE(1,1) $ TOLER(1,2)= 0.01*VALUE(1,1)
TOLER(2,1)= 0.01*VALUE(2,1) $ TOLER(2,2)= 0.01*VALUE(2,1) 
TOLER(3,1)= 0.01*VALUE(3,1) $ TOLER(3,2)= 0.01*VALUE(3,1) 

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC