!******************************************************************************!
! TITLE: CFVR8720 - AISC-LRFD 14: Flexure Checking of an I Section, Strong Axis
! SUBTITLE: Flexure checking according to AISC-LRFD 14 of an I-shape section 
! SUBTITLE: in the strong axis with a laterally unbraced length of 5 ft.
!
! DESCRIPTION: A steel beam is subjected to auniform load of 1.2 kip/ft.
! DESCRIPTION:
! DESCRIPTION: The beam has a length of 35 ft. and a laterally unbraced length of 5 ft.
! DESCRIPTION: 
! DESCRIPTION: Section material properties:
! DESCRIPTION:   A529Gr50  ,  Fy = 50 ksi, Fu = 65 ksi
! DESCRIPTION:
! DESCRIPTION: Geometric properties:
! DESCRIPTION:   W 18x50, Zx = 101 in.^3 
! DESCRIPTION 
! DESCRIPTION: The aim of the example is to obtain the flexure criterion
! DESCRIPTION: according to AISC-LRFD 14.
! DESCRIPTION:

! ELEMENT TYPE: BEAM3
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Steel
! KEYWORD4: Code Checking/Design
! KEYWORD5: AISC14
!
!*******************************************************************************

FINISH
~CFCLEAR,,1
NomFile='CFVR8720'
/TITLE, %NomFile%, AISC-LRFD 14: Flexure Checking of I section Strong Axis

!-------------------------------------------------------------------------------
! Model definition
!-------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
~UNITS,,LENG,in
~UNITS,,TIME,S
~UNITS,,FORC,KIPS
~UNITS,,PRES,,0 ,ksi
~CODESEL,AISC14
   

/PREP7

! Materials
~CFMP,1,LIB,STEEL,ASTM,A529Gr50 

! Element Types
ET,1,BEAM3  ! Type 1: 2D Beam

! Cross Section
~SSECLIB,1,1,51,148   !W 18x50  

!Member Properties
~MEMBPRO,1,AISC14,ALL,420.00,1.000,1.000,1.000,1.000,60.00,  

! Beam & Shell Property
~BMSHPRO,1,BEAM,1,1,,,3,1,0,,Beam 1

! Nodes
N,1,0.,0.
N,2,210.,0.
N,3,420.,0.

! Elements
E,1,2
E,2,3
  
/SOLU
! Loads
D,1, , , , , ,UX,UY, , , ,   
D,3, , , , , , ,UY, , , ,
SFBEAM,1,1,PRES,1.2/12, , , , , ,0 
SFBEAM,2,1,PRES,1.2/12, , , , , ,0 


SOLVE

/POST1
~CFSET,,1,1 
~CHKSTL,BENDING,Z,LRFD   
!-------------------------------------------------------------------------------------
! DATA CHECK
!-------------------------------------------------------------------------------------
! Data comparison number
NComp = 3
NComp_ch = 0

! Marix dim.
*DIM,LABEL,CHAR,Ncomp,1
*DIM,LABEL_CH,CHAR,Ncomp_ch,1
*DIM,VALUE,,Ncomp,3
*DIM,VALUE_CH,CHAR,Ncomp_ch,3
*DIM,TOLER,,Ncomp,2


! Labels
LABEL(1,1) = 'CHK_LTB'
LABEL(2,1) = 'CRT_YLD'
LABEL(3,1) = 'CRT_TOT'

! Correct values
VALUE(1,1) = 0
VALUE(2,1) = 0.485
VALUE(3,1) = 0.485


! Comparison

~CFGET,VALUE(1,2),ELEMENT,1,RESULT,CHK_LTB,J
~CFGET,VALUE(2,2),ELEMENT,1,RESULT,CRT_YLD,J
~CFGET,VALUE(3,2),ELEMENT,1,RESULT,CRT_TOT,J


! Warning and error tolerances
TOLER(1,1)= 0.003*VALUE(1,1) $ TOLER(1,2)= 0.003*VALUE(1,1)
TOLER(2,1)= 0.003*VALUE(2,1) $ TOLER(2,2)= 0.003*VALUE(2,1) 
TOLER(3,1)= 0.003*VALUE(3,1) $ TOLER(3,2)= 0.003*VALUE(3,1) 

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC