!******************************************************************************!
! TITLE: CFVR8859 - AASHTO12: Shear Checking of a Pipe Section
! SUBTITLE: Shear checking according to AASHTO12 Pipe section.
!
! DESCRIPTION: A steel beam is subjected a uniform load of 1 k/in 
! DESCRIPTION: 
! DESCRIPTION:
! DESCRIPTION: The beam has a length of 100 in.
! DESCRIPTION: 
! DESCRIPTION: Section material properties:
! DESCRIPTION:   A572Gr50 ,  Fy = 50 ksi , Fu = 65 ksi
! DESCRIPTION:
! DESCRIPTION: Geometric properties:
! DESCRIPTION:  P 5: OD=5.563 in ; tkwall= 0.258 in  .
! DESCRIPTION 
! DESCRIPTION: Member property : LV = 50 in
! DESCRIPTION: 
! DESCRIPTION:
! DESCRIPTION:  The aim of the example is to obtain the shear criterion 
! DESCRIPTION:  according to AASHTO 2010. 
! DESCRIPTION:
!
! ELEMENT TYPE: BEAM3
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Steel
! KEYWORD4: Code Checking/Design
! KEYWORD5: AASHTO12
!
!*******************************************************************************

FINISH
~CFCLEAR,,1
NomFile='CFVR8859'
/TITLE, %NomFile%, AASHTO12: Shear Checking Pipe Section

!-------------------------------------------------------------------------------
! Model definition
!-------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
~UNITS,,LENG,IN
~UNITS,,TIME,S
~UNITS,,FORC,KIPS
~CODESEL,AASHTO12,EC2-08,,,EC8-04
   

/PREP7

! Materials
~CFMP,1,LIB,STEEL,ASTM,A572Gr50 


! Element Types
ET,1,BEAM3  ! Type 1: 2D Beam

! Cross Section
~SSECLIB,1,1,62,11   !P 5

! Member Properties
~MEMBPRO,1,AASHTO12,ALL,100.0,1.000,1.000,1.000,1.000,0.000,1.000,1.000,50, 


! Beam & Shell Property
~BMSHPRO,1,BEAM,1,1,,,3,1,0,,Beam 1

! Nodes
N,1,0.,0.
N,2,50.,0.
N,3,100.,0.

! Elements
E,1,2
E,2,3

/SOLU
! Loads
D,1, , , , , ,UX,UY, , , ,   
D,3, , , , , , ,UY, , , ,
SFBEAM,1,1,PRES,1, , , , , ,0
SFBEAM,2,1,PRES,1, , , , , ,0

SOLVE

/POST1
~CFSET,,1,1 
~CHKSTL,SHEAR
!-------------------------------------------------------------------------------------
! DATA CHECK
!-------------------------------------------------------------------------------------
! Data comparison number
NComp = 2
NComp_ch = 0

! Marix dim.
*DIM,LABEL,CHAR,Ncomp,1
*DIM,LABEL_CH,CHAR,Ncomp_ch,1
*DIM,VALUE,,Ncomp,3
*DIM,VALUE_CH,CHAR,Ncomp_ch,3
*DIM,TOLER,,Ncomp,2


! Labels
LABEL(1,1) = 'VN'
LABEL(2,1) = 'CRT_TOT'


! Correct values
VALUE(1,1) = 62.35
VALUE(2,1) = 0.80


! Comparison

~CFGET,VALUE(1,2),ELEMENT,1,RESULT,VN,I
~CFGET,VALUE(2,2),ELEMENT,1,RESULT,CRT_TOT,I

! Warning and error tolerances
TOLER(1,1)= 0.005*VALUE(1,1) $ TOLER(1,2)= 0.005*VALUE(1,1)
TOLER(2,1)= 0.005*VALUE(2,1) $ TOLER(2,2)= 0.005*VALUE(2,1) 


!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC