Element types used in the model: BEAM4

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1
   NomFile='CFVR2910'
 /TITLE,%NomFile%, BENDING + AXIAL FORCE DESIGN ACCORDING TO SP-52-101-03

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
 ~UNITS,,LENG,M
 ~UNITS,,TIME,S
 ~UNITS,,FORC,KN
 ~CODESEL,,SP52101

! Preprocessor
  /PREP7

! Material Definition
 ~CFMP,1,LIB,CONCRETE,SP52101,B30
 ~CFMP,2,LIB,REINF,SP52101,A500

! Element Type Definition
  ET,1,Beam4                            ! Element Type 1: 2D Beam

! Cross-section definition
 ~CSECDMS,1,REC,1,0.5,0.3
 
! Reinforcement definition 
 ~RNFDEF,1,1,2,2,0,0.04,1.0E-04  ! Top reinforcement = 1cm2
 ~RNFDEF,1,2,2,4,0,0.04,1.0E-04  ! Bottom reinforcement = 1cm2
 
! Beam & Shell property
 ~BMSHPRO,1,BEAM,1,1,,,4,1,0,,Beam Property

! Model Construction
  N,1                                   ! Nodes input
  N,5,5
  FILL,1,5
  E,1,2                                 ! Elements input
  EGEN,4,1,1,1
  D,1,ALL                               ! Boundary conditions

/SOLU
  M=190               ! 190 kN*m vertical lumped force
  H=-900              ! 900 kN compression axial force
  F,5,FX,H
  F,5,MZ,M
  SOLVE               ! Calculation

/POST1

! Postprocessor
  ~CFSET,,1,1       ! Read first load step

! Bending + Axial design for rectangular sections according to SP-52-101-03
  ~DIMCON,2DB,,,1,5 
  
!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 2
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2


! Labels
  LABEL(1,1) = 'CRT_TOT'
  LABEL(2,1) = 'REINFACT'

! Correct values
  VALUE(1,1)=1.00
  VALUE(2,1)=2.66

! Comparison
 ~PLLSCON,CRT_TOT
 *GET,VALUE(1,2),ELEM,4,ETAB,CFETAB_I
 ~PLLSCON,REINFACT
 *GET,VALUE(2,2),ELEM,4,ETAB,CFETAB_J

! Warning and error tolerances
  TOLER( 1, 1)= 1E-02 $ TOLER( 1, 2)= 1E-02
  TOLER( 2, 1)= 1E-02 $ TOLER( 2, 2)= 1E-02

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC