Element types used in the model: BEAM188

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1
  NomFile='CFVR7601'
  /TITLE, %NomFile%, Influence Lines: 5 spans continuous beam

! ---------------------------------------------------------------------------------
! Model definition
! ---------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
~UNITS,SI              ! Set International System units

/PREP7
! Preprocessor
! --------------------------------------------------
! Element type
ET,1,BEAM188,,,2

! Material: EC3-Steel
~CFMP,1,LIB,STEEL,EC3,Fe 360

! Beams section
~SSECLIB,1,1,1,16      ! IPE 500 (H shaped)
~SECMDF,1,ROTATE,,,90  ! IPE 500 rotation
~BMSHPRO,1,BEAM,1,1,,,188,0,0,,Beam 1

! Solid Modeling
TYPE,1 $ MAT,1 $ SECNUM,1
K,1
K,2,2
K,3,4
K,4,8
K,5,12
K,6,16
K,7,20
K,100, 100, 100  ! BEAM188 K-Orientation point

! Boundary Conditions I: Articulated Supports
DK,1,ux,0 $ DK,1,uy,0
DK,3,ux,0 $ DK,3,uy,0
DK,4,ux,0 $ DK,4,uy,0
DK,5,ux,0 $ DK,5,uy,0
DK,6,ux,0 $ DK,6,uy,0
DK,7,ux,0 $ DK,7,uy,0
L,1,2  ! Line 1
L,2,3  !      2
L,3,4  !      3
L,4,5  !      4
L,5,6  !      5
L,6,7  !      6

! Meshing
ESIZE,0.5                   ! Element size
LATT,ALL,10,,1,,100,,1
LMESH,ALL

! Boundary conditions II: Plane structure
D,ALL,UZ,0
D,ALL,ROTX,0
D,ALL,ROTY,0
NSEL,ALL $ ESEL,ALL

!  INFLUENCE LINE CALCULATION

! Target node
nn=NODE(kx(2),ky(2),0)

! Bending moment I.L.    -----------------------------------------------
~ILOPEN,5,MZ,FY,nn,,,,1
/POST1

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparision number
  NComp = 4
  NComp_ch = 0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

  ! Correct data, obtained data
!--------------------------------------------------------------------------------------
  ~CFSET,0,1,LAST,
  VALUE( 1,1) = -0.79930846   $  *GET,VALUE(1,2),NODE,nn,U,Y
  VALUE( 2,1) = 82            $  *GET,VALUE(2,2),NODE,,COUNT
  CMSEL,S,CFINFLINE5_NEGATIVE_N
  VALUE( 3,1) = 28            $  *GET,VALUE(3,2),NODE,,COUNT
  ALLSEL

! Closing the Influence Line
/PREP7
~ILCLOSE

! Correct values
!---------------------------------------------------------------------------
  VALUE( 4,1) = 81            $  *GET,VALUE( 4,2),NODE,,COUNT

! Warning and error tolerances
!------------------------------------------------------------------------------
   *DO,II,1,NComp
     TOLER(II, 1)= 1E-6 $ TOLER(II, 2)= 1E-6
   *ENDDO

!--------------------------------------------------------------------------------------
! Results Comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC