Element types used in the model: BEAM3

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

  FINISH
  ~CFCLEAR,,1
  NomFile='CFVR2216'
 /TITLE, %NomFile%, SHEAR DESIGN ACCORDING TO BS8110

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,,LENG,M
  ~UNITS,,TIME,S
  ~UNITS,,FORC,MP
  ~CODESEL,,BS8110

! Preprocessor
  /PREP7

! Parameters
  L = 10     ! Length between supports, in m
  b = 0.3    ! Cross-section width in m.
  h = 0.5    ! Depth in m.
  Q = 7.5    ! Uniform distributed load in Mp/m

! Material Definition
  ~CFMP,1,LIB,CONCRETE,BS8110,C35
  ~CFMP,2,LIB,REINF,BS8110,Gr460A

! Element Type Definition
  ET,1,Beam3                            ! Element Type 1: 2D Beam

! Cross-section definition
  ~CSECDMS,1,REC,1,h,b

! Reinforcement definition
  ~RNFDEF,1,SHEAR,2,0.0,0.0,1E-4,0.0   ! Shear reinf.

! Code properties definition
  ~SECMDF,1,BS8110PR,REC,,5e-002

! Beam & Shell property
  ~BMSHPRO,1,BEAM,1,1,,,3,1,0,,Beam property

! Model
  N,1
  N,21,L
  FILL,1,21
  E,1,2
  EGEN,20,1,1,1
! Boundary conditions
  D, 1,UX,0
  D, 1,UY,0
  D,21,UY,0

/SOLU
! Solution
  SFBEAM,ALL,1,PRES,Q
  SOLVE               ! Calculation

/POST1
! Postprocessor
  ~CFSET,,1,1

! Shear in Y design
  ~DIMCON,SHT,SHEAR

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparision number
  NComp = 4
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'VU1'
  LABEL(2,1) = 'VS'
  LABEL(3,1) = 'VC'
  LABEL(4,1) = 'ASSH'

! Correct Values
  VALUE(1,1) = 65.153
  VALUE(2,1) = 27.855
  VALUE(3,1) =  5.895
  VALUE(4,1) =  0.138E-2

! Comparison
 ~PLLSCON,VU1
 *GET,VALUE(1,2),ELEM,19,ETAB,CFETAB_J
 ~PLLSCON,VS
 *GET,VALUE(2,2),ELEM,19,ETAB,CFETAB_J
 ~PLLSCON,VC
 *GET,VALUE(3,2),ELEM,19,ETAB,CFETAB_J
 ~PLLSCON,ASSH
 *GET,VALUE(4,2),ELEM,19,ETAB,CFETAB_J

! Warning and error tolerances
  *DO,II,1,4
    TOLER(II,1)= 1E-3 $ TOLER(II,2)= 1E-3
  *ENDDO

!--------------------------------------------------------------------------------------
! Results Comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC