Element types used in the model: BEAM188

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

 FINISH
 ~CFCLEAR,,1
 NomFile='CFVR8666'
 /TITLE, %NomFile%, AISC15: Bending Check 
!--------------------------------------------------------------------------------------
! Model definition
!--------------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
  ~UNITS,,LENG,IN
  ~UNITS,,FORC,KIPS! in, sec, Kips
  ~CODESEL,AISC15

! Parameters
  M  = 396*12	  ! Moment kip-in
  Fyy = 50        ! ksi
  Fuu = 65        ! ksi

/PREP7
! Preprocessor
! --------------------------------------------------
! Materials
 ~CFMP,1,LIB,STEEL,ASTM,A36 
!  ASTM A992 
 ~CFMP,1,NAME,,,ASTM A992
 ~CFMP,1,USER
 ~CFMP,1,AISC15  ,Fy,,Fyy ,1,0,0
 ~CFMP,1,AISC15  ,Fu,,Fuu ,1,0,0
 
! Element Types
  ET,1,188  ! Type 1: 3D Beam
  
! Cross Section W 21x48
  ~SSECDMS,1,I,1,20.6,0.35,8.14,0.43,,19  ! W 21x48
  

! member property: 
  ~MEMBPRO,1,AISC15,ALL,40*12,1.00,1.00,1.00,1.00,0,  

! Beam & Shell Property
  ~BMSHPRO,1,BEAM,1,1,,,188,1,0,,Beam 1

! W 21x48 data
  ~SECMDF,1,MECHPROP,A        ,,14.1,2,0,0
  ~SECMDF,1,UPDATE
  ~SECMDF,1,MECHPROP,WZ       ,,93 ,2,0,0 
  ~SECMDF,1,UPDATE
  ~SECMDF,1,MECHPROP,WPZ      ,,107 ,2,0,0
  ~SECMDF,1,UPDATE
  ~UPDATE,BMSHPRO  
 
! Nodes
  N,1
  N,2,,2
  
! Elements
  SECNUM,1
  REAL,1
  E,1,2  

  /SOLU
! Solution
! --------------------------------------------------
! Constrains
  D,1,ALL
  
! Apply Load
  F,ALL,MZ,M
  
! Solve
  SOLVE
  
  /POST1
! Postprocessor
! --------------------------------------------------
! Read results
  ~CFSET,,1                ! First load case
  
! Checking
  ~CHKSTL,BENDING,Z,LRFD  
  ~CHKSTL,BENDING,Z,ASD  
 
 !--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 11
  NComp_ch = 0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'MU'
  LABEL(2,1) = 'MP'
  LABEL(3,1) = 'MN_YLD'
  LABEL(4,1) = 'MN_FLB'  
  LABEL(5,1) = 'CLS_BEND'
  LABEL(6,1) = 'CRT_LRFD'
  LABEL(7,1) = 'CRT_ASD'
  LABEL(8,1) = 'CRT_YLDL'  
  LABEL(9,1) = 'CRT_FLBL'  
  LABEL(10,1) = 'CRT_YLDA'  
  LABEL(11,1) = 'CRT_FLBA'        

! Correct values
  VALUE(1,1)= 4752               ! required flexural strength
  VALUE(2,1)= 5350            ! Plastic bending moment 
  VALUE(3,1)= 5350            ! Nominal Flexural Strength for yielding limit state
  VALUE(4,1)= 5310            ! Nominal Flexural Strength of compression flange local buckling
  VALUE(5,1)= 2.00            ! NONCOMPACT FLANGES 
  VALUE(6,1)= 0.994   ! LRFD CRITERION   
  VALUE(7,1)= 1.49   ! ASD CRITERION  
  VALUE(8 ,1)= 0.987   ! Yielding CRITERION LRFD   
  VALUE(9 ,1)= 0.994   ! flange local buckling limit state CRITERION LRFD     
  VALUE(10,1)= 1.48   ! Yielding CRITERION ASD   
  VALUE(11,1)= 1.49  ! flange local buckling limit state CRITERION ASD     

! Comparison

~CFSET,1   ! LRFD 
 ~CFGET,VALUE(1,2),ELEMENT,1,RESULT,MU,I 
 ~CFGET,VALUE(2,2),ELEMENT,1,RESULT,MP,I 
 ~CFGET,VALUE(3,2),ELEMENT,1,RESULT,MN_YLD,I  
 ~CFGET,VALUE(4,2),ELEMENT,1,RESULT,MN_FLB,I   
 ~CFGET,VALUE(5,2),ELEMENT,1,RESULT,CLS_BEND,I
 ~CFGET,VALUE(6,2),ELEMENT,1,RESULT,CRT_TOT,I
 ~CFGET,VALUE(8,2),ELEMENT,1,RESULT,CRT_YLD,I
 ~CFGET,VALUE(9,2),ELEMENT,1,RESULT,CRT_FLB,I   
 
~CFSET,2  ! ASD 
 ~CFGET,VALUE(7,2),ELEMENT,1,RESULT,CRT_TOT,I
 ~CFGET,VALUE(10,2),ELEMENT,1,RESULT,CRT_YLD,I
 ~CFGET,VALUE(11,2),ELEMENT,1,RESULT,CRT_FLB,I   

! Warning and error tolerances
*DO,JJ,1,11
 TOLER(JJ,1)= 0.04*VALUE(JJ,1) $ TOLER(JJ,2)= 0.04*VALUE(JJ,1)
*ENDDO
  
!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC