Element types used in the model: BEAM4

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1
   NomFile='CFVR1254'
  /TITLE,%NomFile%, Shear and torsion checking according to ITER Structural Design Code for Buildings

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,,LENG,M
  ~UNITS,,TIME,S
  ~UNITS,,FORC,MP
  ~CODESEL,EC3-92,ITER,EC2-08,,EC8-04

! Preprocessor
  /PREP7

! Parameters
  L=1              ! Length in m
  b=.4             ! Cross-section width in m.
  h=.3             ! Depth in m.
  T=0.95*1.6       ! Torsional moment in Mp*m
  Q=4.7*1.6        ! Maximum concomitant design shear force in Mp

! Material Definition
 ~CFMP,1,LIB,CONCRETE,EC2,C25/30
 ~CFMP,2,LIB,REINF,EC2,S400

! Element Type Definition
  ET,1,Beam4                                 ! Element Type 1: 3D Beam

! Cross-section definition
 ~CSECDMS,1,REC,1,0.3,0.4
! Reinforcement definition
  ~RNFDEF,1,SHEAR,2,0.0,0.0,1.2E-3,0.0     ! Shear reinforcement
  ~RNFDEF,1,TORSION,2,3.03e-4,,,,3.27e-4,  ! Torsional reinforcement
! Beam properties
 ~BMSHPRO,1,BEAM,1,1,,,4,1,0,,

! Model Construction
  N,1                                    ! Nodes input
  N,5,L
  FILL,1,5

  E,1,2                                  ! Elements input
  EGEN,4,1,1,1

  D,1, , , , , ,ALL                      ! Constraint conditions

/SOLU
  F,5,FY,-Q
  F,5,MX,T
  SOLVE               ! Calculation

/POST1
! Postprocessor
  ~CFSET,,1,1       ! Read first load step

! Torsion checking
  ~CHKCON,SHT,BOTH

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 10
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'VRDC'
  LABEL(2,1) = 'VRDS'
  LABEL(3,1) = 'VRDMAX'
  LABEL(4,1) = 'CRTSHR'
  LABEL(5,1) = 'TRDMAX'
  LABEL(6,1) = 'TRD'
  LABEL(7,1) = 'ALT'
  LABEL(8,1) = 'CRTTRS'
  LABEL(9,1) = 'CRT_6'
  LABEL(10,1) = 'CRT_TOT'

! Correct values
  VALUE(1,1)=4.77
  VALUE(2,1)=9.956
  VALUE(3,1)=46.924
  VALUE(4,1)=0.755
  VALUE(5,1)=5.8844
  VALUE(6,1)=1.447
  VALUE(7,1)=3.364e-4
  VALUE(8,1)=1.0504
  VALUE(9,1)=0.418569
  VALUE(10,1)=1.0504

! Comparison

 ~PLLSCON,VRDC
 *GET,VALUE(1,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,VRDS
 *GET,VALUE(2,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,VRDMAX
 *GET,VALUE(3,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,CRTSHR
 *GET,VALUE(4,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,TRDMAX
 *GET,VALUE(5,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,TRD
  *GET,VALUE(6,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,ALT
  *GET,VALUE(7,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,CRTTRS
  *GET,VALUE(8,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,CRT_6
  *GET,VALUE(9,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,CRT_TOT
  *GET,VALUE(10,2),ELEM,1,ETAB,CFETAB_I

! Warning and error tolerances
  TOLER( 1,1)= 1E-01 $ TOLER( 1,2)= 1E-01
  TOLER( 2,1)= 1E-01 $ TOLER( 2,2)= 1E-01
  TOLER( 3,1)= 1E-01 $ TOLER( 3,2)= 1E-01
  TOLER( 4,1)= 1E-03 $ TOLER( 4,2)= 1E-03
  TOLER( 5,1)= 1E-01 $ TOLER( 5,2)= 1E-01
  TOLER( 6,1)= 1E-01 $ TOLER( 6,2)= 1E-01
  TOLER( 7,1)= 1E-05 $ TOLER( 7,2)= 1E-05
  TOLER( 8,1)= 1E-03 $ TOLER( 8,2)= 1E-03
  TOLER( 9,1)= 1E-03 $ TOLER( 9,2)= 1E-03
  TOLER(10,1)= 1E-03 $ TOLER(10,2)= 1E-03

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC