Element types used in the model: BEAM3

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1
  NomFile='CFVR4307'
  /TITLE, %NomFile%, Seismic analysis according to IT3274 of a 2D Frame

! ----------------------------------------------------------------------
! Model definition
! ----------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,SI
  ~CODESEL,,,,,IT3274

/PREP7
! Preprocessor
! ----------------------------------------------------------------------
! Define materials
  ~CFMP,1,LIB,STEEL,EA,A42  ! Material: Steel A-42
! Define element types
  ET,1,BEAM3 ! Beam 2D
! Define sections
  ~SSECLIB,1,1,6,11                ! Real 1: HEB-300 for Beam3 (Columns)
  ~SSECLIB,2,1,6,15                ! Real 2: HEB-400 for Beam3 (Beams)
  ~BMSHPRO,1,BEAM,1,1,,,3,,0,,Concrete Section  ! Constant Section (Sec 1)
  ~BMSHPRO,2,BEAM,2,2,,,3,,0,,Concrete Section	! Constant Section (Sec 2)

! Solid model
  ! Column at X=0
    K,1
    K,2,,4
    K,3,,3.5+4
    K,4,,3.5+4+3.5
    L,1,2
    L,2,3
    L,3,4
  ! Columns at X=5 and 10
    LGEN,3,1,3,,5,,,4
  ! Column Attributes
    LATT,1,1,1
  ! Beams
    L,2,6
    LGEN,2,10,10,,5,,,4
    LGEN,3,10,11,,,3.5,,1
  ! Beams Attributes
    LSEL,S,,,10,15
    LATT,1,2,1
    LSEL,ALL
! Constraints
    DK,1,ALL
    DK,5,ALL
    DK,9,ALL
! Mesh
    ESIZE,,6      ! 6 Elements in each member
    LMESH,ALL
    /ESHAPE,1
    EPLOT
    /IMAGE,SAVE,%NomFile%,BMP

/SOLU
! CivilFEM Seismic Design
! ----------------------------------------------------------------------
! Define spectrum
  ~DEFSPEC,ALL,1.2753,A,DESIGN,1,1,5,
! Get Modes
  ~MODLSOL,20 ! Get 20 modes
! Combine the modes
  ~CMBMOD,HORIZONT,VERTICAL,NONE,0,0.0001

/POST1
  ~CFSET,,2
! Postprocessor
! ----------------------------------------------------------------------
! Plot of the bending moments about the Z axis
  ~PLLSFOR,M,Z,-1

! ----------------------------------------------------------------------
! DATA CHECK
! ----------------------------------------------------------------------
! Data comparison number
  NComp    =  6
  NComp_ch =  0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
! ----------------------------------------------------------------------
  LABEL(1)  = 'FX_06_J'
  LABEL(2)  = 'FY_06_J'
  LABEL(3)  = 'MZ_06_J'
  LABEL(4)  = 'FX_66_J'
  LABEL(5)  = 'FY_66_J'
  LABEL(6)  = 'MZ_66_J'

! Correct data
! ----------------------------------------------------------------------
  VALUE(1,1) = 13294.44
  VALUE(2,1) =  6760.35
  VALUE(3,1) = 11640.26
  VALUE(4,1) =  1418.80
  VALUE(5,1) =  6864.19
  VALUE(6,1) = 19273.20

! Obtained data
! ----------------------------------------------------------------------
  ~CFGET,VALUE(1,2),ELEMENT, 6,FORCE,FX,J
  ~CFGET,VALUE(2,2),ELEMENT, 6,FORCE,FY,J
  ~CFGET,VALUE(3,2),ELEMENT, 6,FORCE,MZ,J
  ~CFGET,VALUE(4,2),ELEMENT,66,FORCE,FX,J
  ~CFGET,VALUE(5,2),ELEMENT,66,FORCE,FY,J
  ~CFGET,VALUE(6,2),ELEMENT,66,FORCE,MZ,J

! Warning and error tolerances
! ----------------------------------------------------------------------
   *DO,II,1,6
     TOLER(II, 1)= 10 $ TOLER(II, 2)= 10
   *ENDDO

! ----------------------------------------------------------------------
! Results comparison
! ----------------------------------------------------------------------
  COMPARA.MAC