Element types used in the model: BEAM4, MASS21

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1
   NomFile='CFVR4303'
  /TITLE, %NomFile%, IT3274: Seismic Analysis (Elastic spectrum) Z-axis

! ----------------------------------------------------------------------
! Model definition
! ----------------------------------------------------------------------
! CivilFEM Setup: Code & Units
~UNITS,,LENG,CM
~UNITS,,TIME,S
~UNITS,,FORC,KP
~CODESEL,,,,,IT3274
/PREP7
! Preprocessor
! ----------------------------------------------------------------------
! Materials: A-42
 ~CFMP,1,LIB,STEEL,EA,A42
! Modify density (Rho = 0)
 ~CFMP,1,USER
 ~CFMP,1,DatGen,RHO,,0
! Element Types
  ET,1,BEAM4   ! Type 1: 3D Beam
  ET,2,MASS21  ! Type 2: Mass
! Sections
 ~SSECLIB,1,1,1,1   !IPE 80
 ~BMSHPRO,1,BEAM,1,1,,,4,,0,,Steel

! Nodes
  L = 10              ! L    : Bar length
  N, 1
  N,10,L

! Elements
  TYPE,1
  MAT ,1
  REAL,1
  EN,1,1,10
  EPLOT
! Parameters
  *GET,AR20,EX,1         		         ! Ex   : Elastic Modulus
  ~CFGET,AR22,SECTION,1,MECHPROP,A,,2    ! Area : Bar area
  ~CFGET,AR23,SECTION,1,MECHPROP,IZZ,,2  ! Izz  : Moment of inertia
  ~CFGET,AR24,SECTION,1,MECHPROP,IYY,,2  ! Iyy  : Moment of inertia

! Spectrum definition
  ~DEFSPEC,ALL,1.2753,A,LINEAR,1,1,5,

  pi = 3.141592654

! ----------------------------------------------------------------------
! DATA CHECK
! ----------------------------------------------------------------------
! Data comparision number
  NComp = 40
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

*DO,ARG1,1,20
   /PREP7
   ~CFGET,AR26,SEISM,,SPEC,TH,,ARG1,1   ! Period
  ! Labels
   LABEL(ARG1,1) = 'Sa(%ARG1%)z'
   LABEL(20+ARG1,1) = 'Sa(%ARG1%)z'

   AR25=12*AR20*AR24/L**3     ! Bending rigidity around Y axis
   AR27=AR25*(AR26/(2*pi))**2  ! Mass applied at end
   R,2,0,0,AR27
   TYPE,2
   MAT, 1
   REAL,2
   EN,2,10
   FINISH
   /SOLU

 ! Displacements
   D,1,,,,,,ALL
   D,10,,,,,UX,UY,,ROTX,ROTY,ROTZ
   ~MODLSOL,1
   ~CMBMOD,NONE,NONE,HORIZONT,0,0.0001
 ! Query results
   *GET,ARG5,NODE,10,U,Z
 ! Correct values
   VALUE(20-ARG1+1,1)=ARG5*AR25/AR27 ! Acceleration
 ! Obtained values
   ~CFGET,VALUE(20-ARG1+1,2),SEISM,,SPEC,SDH,,ARG1,1	 ! Y components of elastic horizontal spectrum
   ~CFGET,VALUE(40-ARG1+1,2),SEISM,,SPEC,SDH,,ARG1,1	 ! Y components of elastic horizontal spectrum
   ! CivilFEM gives the spectrum Normalized by gravity.
   ! To compare it must be changed to acceleration user units.
   VALUE(20-ARG1+1,2) = VALUE(20-ARG1+1,2)*981
   VALUE(40-ARG1+1,2) = VALUE(40-ARG1+1,2)*981
   /PREP7
   EDELE,2
*ENDDO

! Correct values
! ----------------------------------------------------------------------
   VALUE(40,1) = 0.2550E-01
   VALUE(39,1) = 0.3395E-01
   VALUE(38,1) = 0.4742E-01
   VALUE(37,1) = 0.7085E-01
   VALUE(36,1) = 0.1171
   VALUE(35,1) = 0.2295
   VALUE(34,1) = 0.6376
   VALUE(33,1) = 0.7357
   VALUE(32,1) = 0.8695
   VALUE(31,1) = 1.062
   VALUE(30,1) = 1.366
   VALUE(29,1) = 1.912
   VALUE(28,1) = 3.188
   VALUE(27,1) = 3.188
   VALUE(26,1) = 2.914
   VALUE(25,1) = 2.641
   VALUE(24,1) = 2.368
   VALUE(23,1) = 2.095
   VALUE(22,1) = 1.821
   VALUE(21,1) = 1.548

! Warning and error tolerances
! ----------------------------------------------------------------------
   *DO,II,1,NComp
     TOLER(II, 1)= 0.001 $ TOLER(II, 2)= 0.001
   *ENDDO

! ----------------------------------------------------------------------
! Results Comparison
! ----------------------------------------------------------------------
  COMPARA.MAC