Element types used in the model: BEAM3

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

  FINISH
  ~CFCLEAR,,1
  NomFile='CFVR2307'
  /TITLE, %NomFile%, Steel checking according to LRFD

!--------------------------------------------------------------
! Initial data
!--------------------------------------------------------------
! CivilFEM SETUP
  ~CODESEL,LRFD,EC2,,,EC8-94
  ~UNITS,,MONE,EURO
  ~UNITS,,LENG,FT
  ~UNITS,,TIME,S
  ~UNITS,,FORC,KIPS
  ~UNITS,,PRES,,0,uuP
  ~UNITS,,MASS,,0,uuM

/PREP7
! Geometry: Lateral support at the middle and ends
  LBEAM = 50   ! Length of the beam (feet)
  C_b = 1.30   ! Bending coefficient
  Lb  = 25     ! Lateral support length
  NELEM = 10   ! Number of elements
! Load
  Wu = 1.2*(0.2+0.09) + 1.6*0.8   ! Factored load

! Section W 27*84
  ~SSECLIB,1,1,51,91   ! W 27x84
! Material A36 steel
  ~CFMP,1,LIB,STEEL,ASTM,A36
! Element type
  ET,1,Beam3
! Beam Properties
  ~BMSHPRO,1,BEAM,1,1,,,3,1,0,,Beam 1
! Member properties
  ~MEMBPRO,1,LRFD,ALL,LBEAM,1.0,1.0,1.0,C_b,Lb,
  ~MEMBPRO,1,NLMOD,ALL,0
  ~MEMBPRO,1,NAME,Member Property 1
! Model
  N,1,
  N,NELEM+1,LBEAM,0
  NGEN,NELEM,1,1,,,LBEAM/NELEM
  E,1,2
  EGEN,NELEM,1,1,,

/SOLU
  D,1,UX
  D,1,UY
  D,NELEM+1,UY
  SFBEAM,ALL,1,PRES,WU
  SOLVE

/POST1
  ~CFSET,,1
  ~CHKSTL,BENDING

!------------------------------------------------------------------
! DATA CHECK
!------------------------------------------------------------------
! Data comparison number
  NComp    =  4
  NComp_ch =  0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,VALUE,,Ncomp,3
  *DIM,TOLER,,Ncomp,2

! Labels
!------------------------------------------------------------------
  LABEL( 1)  = 'CLS_COMP'
  LABEL( 2)  = 'MP'
  LABEL( 3)  = 'MU'
  LABEL( 4)  = 'CRT_TOT '

! Correct data, obtained data
!------------------------------------------------------------------
  VALUE( 1,1) = 3            $  ~CFGET,value( 1,2),ELEMENT,nelem/2,RESULT,CLS_COMP,J
  VALUE( 2,1) = 732          $  ~CFGET,value( 2,2),ELEMENT,nelem/2,RESULT,MP,J

! The ultimate bending moment is the bending moment at the considered end

  ~CFGET,VALUE( 3,1),ELEMENT,NELEM/2,FORCE,MZ,J
  ~CFGET,value( 3,2),ELEMENT,nelem/2,RESULT,MU,J
  ~CFGET,value( 4,1),ELEMENT,nelem/2,RESULT,CRT_LTB,J
  ~CFGET,value( 4,2),ELEMENT,NELEM/2,RESULT,CRT_TOT,J

! Warning and error tolerances
  TOLER( 1, 1)= 1E-03 $ TOLER( 1, 2)= 1E-03
  TOLER( 2, 1)= 1E-03 $ TOLER( 2, 2)= 1E-03
  TOLER( 3, 1)= 1E-03 $ TOLER( 3, 2)= 1E-03
  TOLER( 4, 1)= 1E-03 $ TOLER( 4, 2)= 1E-03
!------------------------------------------------------------------
! Results comparison
!------------------------------------------------------------------
  COMPARA.MAC