Element types used in the model: BEAM4, MASS21

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1
  NomFile='CFVR1713'
  /TITLE, %NomFile%, Eurocode 8-2004: Vertical type 2 elastic spectrum

! ----------------------------------------------------------------------
! Model definition
! ----------------------------------------------------------------------
! Setup: Code & Units
~UNITS,,LENG,CM
~UNITS,,TIME,S
~UNITS,,FORC,KP
~CODESEL,EC3-92,EC2-91,,,EC8-04
/PREP7
! Preprocessor
! ----------------------------------------------------------------------
! Materials: A-42
 ~CFMP,1,LIB,STEEL,EA,A42
! Modify density (Rho = 0)
 ~CFMP,1,USER
 ~CFMP,1,DatGen ,RHO,,0
! Element Types
  ET,1,BEAM4   ! Type 1: 3D Beam
  ET,2,MASS21  ! Type 2: Mass
! Sections
 ~SSECLIB,1,1,1,1   ! IPE 80
 ~BMSHPRO,1,BEAM,1,1,,,4,,0,,

! Nodes
  L = 10			 ! L    : Bar length
  N, 1
  N,10,L

! Elements
  TYPE,1
  MAT ,1
  REAL,1
  EN,1,1,10
  EPLOT

! Parameters
  *GET,EXX,EX,1         		               ! Ex   : Elastic Modulus
  ~CFGET,IZZ,SECTION,1,MECHPROP,IZZ,,2   ! Izz  : Moment of inertia
  ~CFGET,IYY,SECTION,1,MECHPROP,IYY,,2   ! Iyy  : Moment of inertia

! Seismic Spectrum
  ~DEFSPEC,ALL,1.2753,C,ELASTIC,2,1,1,7

  pi=3.141592654

! ----------------------------------------------------------------------
! DATA CHECK
! ----------------------------------------------------------------------
! Data comparison number
  NComp = 40
  NComp_ch = 0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

*DO,II,1,20
   /PREP7
   ~CFGET,Per,SEISM,,SPEC,TV,,II,2       ! Period
		 ! Labels
			LABEL(   II,1) = 'Sa(%II%)y'
			LABEL(20+II,1) = 'Sa(%II%)y'
			K=12*EXX*IZZ/L**3        ! Bending stiffness around Z axis
			Mass=K*(Per/(2*pi))**2   ! Mass applied at end
			R,2,0,Mass,0
   TYPE,2
   MAT, 1
   REAL,2
   EN,2,10
   FINISH
   /SOLU

 ! Solution
 ! ---------------------------------------------------------------------
 ! Displacements
   D, 1,,,,,,ALL,,,,,
   D,10,,,,,,UX,UZ,ROTX,ROTY,ROTZ,
   ~MODLSOL,1
   ~CMBMOD,NONE,VERTICAL,NONE,0,0.0001,
 ! Query results
   *GET,DispY,NODE,10,U,Y
 ! Correct values
   VALUE(20-II+1,1)=DispY*K/Mass ! Acceleration
 ! Obtained values
   ~CFGET,VALUE(20-II+1,2),SEISM,,SPEC,SDV,,II,2	 ! Y components of spectrum
   ~CFGET,VALUE(40-II+1,2),SEISM,,SPEC,SDV,,II,2	 ! Y components of spectrum
   ! CivilFEM gives the spectrum Normalized by gravity.
   ! To compare it must be changed to acceleration user units.
   VALUE(20-II+1,2) = VALUE(20-II+1,2)*981
   VALUE(40-II+1,2) = VALUE(40-II+1,2)*981
   /PREP7
   EDELE,2
*ENDDO

! Correct values
! ----------------------------------------------------------------------
   VALUE(21,1) = 0.7164  ! T=0.007s
   VALUE(22,1) = 0.8590
   VALUE(23,1) = 1.0015
   VALUE(24,1) = 1.1440
   VALUE(25,1) = 1.2866
   VALUE(26,1) = 1.4291
   VALUE(27,1) = 1.5716  ! TB=0.05s
   VALUE(28,1) = 1.5716  ! TC=0.15s
   VALUE(29,1) = 0.8083
   VALUE(30,1) = 0.5440
   VALUE(31,1) = 0.4100
   VALUE(32,1) = 0.3289
   VALUE(33,1) = 0.2747
   VALUE(34,1) = 0.2357  ! TD=1s
   VALUE(35,1) = 0.0377
   VALUE(36,1) = 0.0147
   VALUE(37,1) = 0.0078
   VALUE(38,1) = 0.0048
   VALUE(39,1) = 0.0033
   VALUE(40,1) = 0.0024  ! T=10s

! Warning and error tolerances
! ----------------------------------------------------------------------
  *DO,II,1,NComp
    TOLER(II, 1)= 1E-03 $ TOLER(II, 2)= 1E-03
  *ENDDO

! ----------------------------------------------------------------------
! Results Comparison
! ----------------------------------------------------------------------
  COMPARA.MAC