Element types used in the model: BEAM3

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1
   NomFile='CFVR4007'
 /TITLE, %NomFile%, SHEAR CHECKING ACCORDING TO GB50010
! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,,LENG,m
  ~UNITS,,TIME,S
  ~UNITS,,FORC,KN
 ~CODESEL,,GB50010

! Preprocessor
  /PREP7

! Parameters
  L=10         ! Length between supports, in m
  b=.3         ! Cross-section width in m.
  h=.5         ! Depth in m.
  Q=4.5*1.5    ! Uniform distributed load in Mp/m

! Material Definition
 ~CFMP,1,LIB,CONCRETE,GB50010,C35
 ~CFMP,2,LIB,REINF,GB50010,HPB235
 ~CFMP,2,GB_S    ,GAMs    ,,1.10

! Element Type Definition
  ET,1,Beam3                            ! Element Type 1: 2D Beam

! Cross-section definition
 ~CSECDMS,1,REC,1,0.5,0.3

! Reinforcement definition
 ~RNFDEF,1,1,2,4,0,0.05,0.6368E-02                  ! Bot. reinf. for bending
 ~RNFDEF,1,2,2,2,0,0.05,0.2283E-02                  ! Top reinf. for bending
 ~RNFDEF,1,SHEAR,2,0.0,0.0, , , , ,4.416e-002,6,2,2 ! Shear reinf.

! Code properties definition
 ~SECMDF,1,GB50010P,REC     ,,5e-002

! Beam properties
  ~BMSHPRO,1,BEAM,1,,,,3,0,0,,Beam property

! Model Construction
  N,1                                   ! Nodes input
  N,21,L
  FILL,1,21

  E,1,2                                 ! Elements input
  EGEN,20,1,1,1

  D,1, , , , , ,UX,UY                   ! Constraint conditions
  D,21, , , , , ,UY

/SOLU
  SFBEAM,ALL,1,PRES,Q
  SOLVE               ! Calculation

/POST1

! Postprocessor
  ~CFSET,,1,1         ! First load step

! Shear in Y checking for rectangular sections according to GB50010
  ~CHKCON,SHT,SHEAR
  ~PLLSCON,CRVRD1,1,

/POST1
~PLLSCON,CRVRD1,1,
~PLLSCON,CRVRD2,1,
~PLLSCON,CRVRD3,1,
~PLLSCON,CRT_TOT,1,

!-------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data Comparison number
  NComp = 4
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'VRD1'
  LABEL(2,1) = 'VRD2'
  LABEL(3,1) = 'VRD3'
  LABEL(4,1) = 'CRT_TOT'

! Correct values
  VALUE(1,1)=0.564E3
  VALUE(2,1)=0.148E3
  VALUE(3,1)=0.303E3
  VALUE(4,1)=0.111

! Comparison
 ~PLLSCON,VRD1
 *GET,VALUE(1,2),ELEM,20,ETAB,CFETAB_J
 ~PLLSCON,VRD2
 *GET,VALUE(2,2),ELEM,20,ETAB,CFETAB_J
 ~PLLSCON,VRD3
 *GET,VALUE(3,2),ELEM,20,ETAB,CFETAB_J
 ~PLLSCON,CRT_TOT
 *GET,VALUE(4,2),ELEM,20,ETAB,CFETAB_J

! Warning and error tolerances
  TOLER( 1,1)= 1E-0 $ TOLER( 1,2)= 1E-0     ! Rounding error accepted
  TOLER( 2,1)= 1E-0 $ TOLER( 2,2)= 1E-0     ! Rounding error accepted
  TOLER( 3,1)= 1E-0 $ TOLER( 3,2)= 1E-0     ! Rounding error accepted
  TOLER( 4,1)= 1E-3 $ TOLER( 4,2)= 1E-3

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC