CFVR3501 - Hoek & Brown Triaxial Test

Triaxial test to check Hoek & Brown failure model.

A 3D cylindrical probe is modeled as shown in the figure to check Hoek & Brown failure model by comparing the results with a triaxial test.
The model is made off a single material with the following properties:

Cohesion (Drucker-Prager) = 0.2 MPa
Internal friction angle (Drucker-Prager) = 30º
Dilatancy (Drucker-Prager) = 20º
Compression strength (Qu) = 50 MPa
Geological Strength Index = 40
m0 = 5
s0 = 1
Modified Hoek & Brown criterion exponent (n) = 0.511

The probe has a radial external pressure of 20 MPa and a vertical presure of 50 MPa.

Element types used in the model: SOLID45

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

The example can be launched on an educational license.

KEYWORDS

Geotechnics

Material Models

Model Statistics
Number of elements	0
Number of nodes	0
Number of civil materials	0
Number of cross sections	0
Number of shell vertices	0

Log file: CFVR3501.DAT

  FINISH
  ~CFCLEAR,,1
  ~CFACTIV,GETC,Y
  NomFile='CFVR3501'
  /TITLE, %NomFile%, Hoek & Brown Triaxial Test

! ----------------------------------------------------------------------
! Setup
! ----------------------------------------------------------------------
  ~CFCONFG,HB,HBSOL,1   ! 1: Automatic
  ~UNITS,,LENG,M
  ~UNITS,,TIME,S
  ~UNITS,,PRES,MPA

/PREP7
! ----------------------------------------------------------------------
! Model data
! ----------------------------------------------------------------------
  *AFUN,DEG
! Dimensions [m]
  PBT_R = 0.05    ! Radius
  PBT_H = 0.20    ! Height

! Material data
  ~CFMP,1,LIB,ROCK,,Flint
  ~CFMP,1,ROCK,PHIDPEFF,,0.2   ! Cohesion
  ~CFMP,1,ROCK,CDPEFF  ,,30.0  ! Friction angle
  ~CFMP,1,ROCK,DELEFF  ,,20.0  ! Dilatancy
  ~CFMP,1,ROCK,KPLA    ,,1
  ~CFMP,1,ROCK,QU      ,,50
  ~CFMP,1,ROCK,GSI     ,,40
  ~CFMP,1,ROCK,HB_M0   ,,5
  ~CFMP,1,ROCK,HB_N    ,,0.511

! Element types
  ET,1,SOLID45

! View point
  /VIEW,1,1,1,1
  /VUP,1,Z

! KeyPoints
! Cylindrical coord. system
  LOCAL,11,1,0,0,0, , , ,1,1,
! Lower section
  K,1,0,0
  K,2,PBT_R,0
  K,3,PBT_R,90
! Upper section
  KGEN,2,ALL,,,0,0,PBT_H/2,10

! Volumes
  V,1,2,3,11,12,13
  CSYS,0

! Mesh
  ELEM_SIZE=0.015 ! Global size

! Mapped mesh areas
  MSHKEY,1    ! 0:Free, 1:Mapped, 2:Mapped if possible
  ESIZE,ELEM_SIZE
  MAT,1 $ REAL,1 $ TYPE,1 $ ESYS,11
  VMESH,ALL
  EPLOT
  /IMAGE, SAVE, %NomFile%,BMP

! Components
! Probe
  ESEL,S,TYPE,,1
  NSLE,S
  CM,E_PROBET,ELEM
  CM,N_PROBET,NODE
! Nodes on symmetry plane Z=0
  NSEL,S,LOC,Z,0
  CM,N_SYMZ,NODE
! Nodes on symmetry plane Y=0
  NSEL,S,LOC,Y,0
  CM,N_SYMY,NODE
! Nodes on symmetry plane X=0
  NSEL,S,LOC,X,0
  CM,N_SYMX,NODE
! Nodes on upper face
  NSEL,S,LOC,Z,PBT_H/2
  CM,N_SUP,NODE
! Nodes on outer face
  CSYS,11
  NSEL,S,LOC,X,PBT_R
  CM,N_EXT,NODE
  CSYS,0
  ALLSEL

! ----------------------------------------------------------------------
! Boundary conditions
! ----------------------------------------------------------------------
  D,N_SYMZ,UZ,0
  D,N_SYMX,UX,0
  D,N_SYMY,UY,0

/SOLU
! ----------------------------------------------------------------------
! Solve
! ----------------------------------------------------------------------
! Pressures
  Pr=  20  ! MPa
  Pz=  50  ! MPa
! Options
  NSUBST,5,,5
  NEQIT,30
  OUTRES,ALL,ALL
! First phase pressures P=Pr
  CSYS,11
  CMSEL,S,E_PROBET $ CMSEL,S,N_EXT $ SF,ALL,PRES,Pr
  CMSEL,S,E_PROBET $ CMSEL,S,N_SUP $ SF,ALL,PRES,Pr
  ALLSELL $ CSYS,0 $ TIME, Pr
  SOLVE
! Second phase pressures P=Pz
  /NERR,0,0
  NSUBST,10,,10
  CSYS,11
  CMSEL,S,E_PROBET
  CMSEL,S,N_SUP
  SF,ALL,PRES,Pz
  ALLSELL
  CSYS,0
  TIME,Pz
  ~HBSOLVE  

! The verification example terminates here. The analysis stops because of an
! unconverged solution which gives the value of the pressure limit.
! It is necessary to launch CFVR3501B.MAC to continue the verification.

! CFVR3501.DAT is reproduced here:
!  FINISH
!  ~CFCLEAR,,1
!  ~CFACTIV,GETC,Y
!  NomFile='CFVR3501'
!  /TITLE, %NomFile%, Hoek & Brown Triaxial Test
!! ----------------------------------------------------------------------
!! Setup
!! ----------------------------------------------------------------------
!  ~UNITS,,LENG,M
!  ~UNITS,,TIME,S
!  ~UNITS,,PRES,MPA
!/POST1
!  SET,LAST
!  SET,PREVIOUS
!! ----------------------------------------------------------------------
!! DATA CHECK
!! ----------------------------------------------------------------------
!! Data comparison number
!  NComp    =  1
!  NComp_ch =  0
!! Matrix dim.
!  *DIM,LABEL,CHAR,Ncomp,1
!  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
!  *DIM,VALUE,,Ncomp,3
!  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
!  *DIM,TOLER,,Ncomp,2
!  *DIM,Nodes,,Ncomp,1
!  *DIM,COORDX,,Ncomp,1
!  *GET,QULT,ACTIVE,0,SET,TIME
!! Labels, Values and Tolerances
!  LABEL(1,1)  = 'QULT    '
!  VALUE(1,1) = 43.89   $ VALUE(1,2) = QULT
!  TOLER(1,1)= 0.05     $ TOLER(1,2) = 0.05
!! ----------------------------------------------------------------------
!! Results Comparison
!! ----------------------------------------------------------------------
!COMPARA

Contains proprietary and confidential information of Ingeciber, S.A.

CivilFEM Online Help

CFVR3501 - Hoek & Brown Triaxial Test

Triaxial test to check Hoek & Brown failure model.