Element types used in the model: BEAM4

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

  FINISH
  ~CFCLEAR,,1
  NomFile='CFVR2208'
  /TITLE, %NomFile%, TORSION CHECKING ACCORDING TO BS8110

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
~UNITS,,LENG,M              !m
~UNITS,,TIME,S              !sg
~UNITS,,FORC,MP             !Tn
~CODESEL,,BS8110

! Preprocessor
  /PREP7

! Parameters
  L= 1         ! Length in m
  b= 0.4       ! Cross-section width in m.
  h= 0.3       ! Depth in m.
  T= 1.5       ! Torsional moment in Mp*m
  Q= 1.5       ! Maximum concomitant design shear force in Mp

! Material Definition
  ~CFMP,1,LIB,CONCRETE,BS8110,C50
  ~CFMP,2,LIB,REINF,BS8110,Gr460A

! Element Type Definition
  ET,1,Beam4                            ! Element Type 1: 3D Beam

! Cross-section definition
  ~CSECDMS,1,REC,1,h,b

! Reinforcement definition
 ~RNFDEF,1,TORSION,2,5.0E-4, , , ,8.0E-4

! Beam properties
  ~BMSHPRO,1,BEAM,1,1,,,4,0,0,,Beam properties

! Model
  N,1
  N,5,L
  FILL,1,5
  E,1,2
  EGEN,4,1,1,1
! Boundary conditions
  D,1,ALL,0

/SOLU
! Solution
  F,5,FY,-Q
  F,5,MX,T
  SOLVE

/POST1
! Postprocessor
  ~CFSET,,1,1       ! Read first load step

! Torsion checking according to BS8110
  ~CHKCON,SHT,TORSION

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparision number
  NComp = 4
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'TU1'
  LABEL(2,1) = 'TU2'
  LABEL(3,1) = 'TU3'
  LABEL(4,1) = 'CRT_TOT'

! Correct Values
  VALUE(1,1) = 4.000
  VALUE(2,1) = 1.149
  VALUE(3,1) = 0.27E-3
  VALUE(4,1) = 1.305

! Comparison
 ~PLLSCON,TU1
 *GET,VALUE(1,2),ELEM,3,ETAB,CFETAB_J
 ~PLLSCON,TU2
 *GET,VALUE(2,2),ELEM,3,ETAB,CFETAB_J
 ~PLLSCON,ALT
 *GET,VALUE(3,2),ELEM,3,ETAB,CFETAB_J
 ~PLLSCON,CRT_TOT
 *GET,VALUE(4,2),ELEM,3,ETAB,CFETAB_J

! Warning and error tolerances
  TOLER( 1,1)= 1E-2 $ TOLER( 1,2)= 1E-2		! Rounding error accepted
  TOLER( 2,1)= 1E-3 $ TOLER( 2,2)= 1E-3
  TOLER( 3,1)= 1E-5 $ TOLER( 3,2)= 1E-5
  TOLER( 4,1)= 1E-3 $ TOLER( 4,2)= 1E-3

!--------------------------------------------------------------------------------------
! Results Comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC