Element types used in the model: BEAM188

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

 FINISH
 ~CFCLEAR,,1
 NomFile='CFVR8679'
 /TITLE, %NomFile%, AISC15: Shear Check 
!--------------------------------------------------------------------------------------
! Model definition
!--------------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
  ~UNITS,,LENG,IN
  ~UNITS,,FORC,KIPS! in, Kips
  ~CODESEL,AISC15

! Parameters
  F  = 120		  ! Force kips
  Fyy = 50        ! ksi
  Fuu = 65        ! ksi

/PREP7
! Preprocessor
! --------------------------------------------------
! Materials
 ~CFMP,1,LIB,STEEL,ASTM,A36 
!  ASTM A500 Grade C 
 ~CFMP,1,NAME,,,ASTM A992
 ~CFMP,1,USER
 ~CFMP,1,AISC15  ,Fy,,Fyy ,1,0,0
 ~CFMP,1,AISC15  ,Fu,,Fuu ,1,0,0
 
 
! Element Types
  ET,1,188  ! Type 1: 3D Beam
  
! Cross Section W 21x48
  ~SSECDMS,1,I,1,20.6,0.35,8.14,0.43,,19  ! W 21x48
  
! Beam & Shell Property
  ~BMSHPRO,1,BEAM,1,1,,,188,1,0,,Beam 1

! W 21x48 data
  ~SECMDF,1,MECHPROP,A        ,,14.1,2,0,0
  ~SECMDF,1,UPDATE
  ~SECMDF,1,MECHPROP,WZ       ,,93 ,2,0,0 
  ~SECMDF,1,UPDATE
  ~SECMDF,1,MECHPROP,WPZ      ,,107 ,2,0,0
  ~SECMDF,1,UPDATE
  ~UPDATE,BMSHPRO 
  
! Nodes
  N,1
  N,2,2
  
! Elements
  SECNUM,1
  REAL,1
  E,1,2  

  /SOLU
! Solution
! --------------------------------------------------
! Constrains
  D,1,ALL
  
! Apply Load
  F,2,FZ,F
  
! Solve
  SOLVE
  
  /POST1
! Postprocessor
! --------------------------------------------------
! Read results
  ~CFSET,,1                ! First load case
  
! Checking
  ~CHKSTL,SHEAR,Y,LRFD  
  ~CHKSTL,SHEAR,Y,ASD  
 
 !--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 4
  NComp_ch = 0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'AW'
  LABEL(2,1) = 'VN'
  LABEL(3,1) = 'CRT_LRFD'
  LABEL(4,1) = 'CRT_ASD'

! Correct values
  VALUE(1,1)=7.00             ! Web area
  VALUE(2,1)=210           ! Nominal shear strength
  VALUE(3,1)=0.6349            ! Total criterion LRFD
  VALUE(4,1)=0.9542            ! Total criterion ASD

! Comparison

~CFSET,1   ! LRFD 
 ~CFGET,VALUE(1,2),ELEMENT,1,RESULT,AW,I 
 ~CFGET,VALUE(2,2),ELEMENT,1,RESULT,VN,I 
 ~CFGET,VALUE(3,2),ELEMENT,1,RESULT,CRT_TOT,I  
 
~CFSET,2  ! ASD 
 ~CFGET,VALUE(4,2),ELEMENT,1,RESULT,CRT_TOT,I

! Warning and error tolerances
*DO,JJ,1,4
 TOLER(JJ,1)= 0.03*VALUE(JJ,1) $ TOLER(JJ,2)= 0.03*VALUE(JJ,1)
*ENDDO
  
!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC