CFVR1005 - Eurocode 3 1992 test: Lateral buckling

Lateral buckling checking according to Eurocode 3 1992.

A steel beam subjected to a surface load of 80 KN/m.
The beam has a length of 6m.
The cross section is a double T section with the following parameters:

A= 11.44E-3 m².
Wy= 322.67E-6 m³.
Wz= 2.209E-3 m³.
Wpy= 473.92E-6 m³.
Wpz= 2.314E-3 m³.

The beam is made of Fe 360 steel.

The aim of the example is to obtain the lateral buckling criterion according to Eurocode 3

Element types used in the model: BEAM3

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

The example can be launched on an educational license.

KEYWORDS

Beam

Cross Section

Steel

Code Checking/Design

Eurocode 3

Model Statistics
Number of elements	6
Number of nodes	7
Number of civil materials	1
Number of cross sections	1
Number of shell vertices	0

Log file: CFVR1005.DAT

  FINISH
  ~CFCLEAR,,1
  NomFile='CFVR1005'
  /TITLE, %NomFile%, Eurocode 3 1992 test: Lateral buckling

! ---------------------------------------------------------------------------------
! Model definition and solve
! ---------------------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,,LENG,M
  ~UNITS,,TIME,S
  ~UNITS,,FORC,KN
  ~CODESEL,EC3-92

/PREP7
! Materiales
  ~CFMP,1,LIB,STEEL,EC3,Fe 360  !Fe 360

! Element types
  ET,1,Beam3 ! Element Type 1: 2D Beam
  FlangeTh  = 0.02
  WebTh = 0.006
! Cross sections
  ~SSECPLT,NEW,2
  ~SSECPLT,PLT,  2,   4,  1, 2, 1,  0,  1,FlangeTh, 0.23, 0.11, 0.23,  0
  ~SSECPLT,PLT,  2,   5,  1, 2, 1,  0,  1,FlangeTh, 0.23,-0.11, 0.23,  0
  ~SSECPLT,PLT,  2,   9,  1, 2, 1,  0,  1,FlangeTh,-0.23, 0.11,-0.23,  0
  ~SSECPLT,PLT,  2,  10,  1, 2, 1,  0,  1,FlangeTh,-0.23,-0.11,-0.23,  0
  ~SSECPLT,PLT,  2,   2,  1, 1, 2,  1,  1,WebTh,0.22,  0,-0.22,0

! Member properties
 ~MEMBPRO,1,EC3,ALL,6,1,1,1.132,0.459,0,1,1,1,.8,0,0,0,1

! Beam properties
 ~BMSHPRO,1,BEAM,2,2,,,3,1,0,,

! Nodes
  N,1
  N,7,6
  FILL,1,7
! Elements
  E,1,2
  EGEN,6,1,1,1
! Boundary conditions
  D,1,,,,,,UX,UY
  D,7,,,,,,UY
! Plot
  /ESHAPE,1
  EPLOT

/SOLU
  P=80*1.5 ! 80 KN/m uniform distributed load
  SFBEAM,ALL,1,PRES,P
  SOLVE

/POST1
! Postprocessor
  ~CFSET,,1,1       !Read the first load step
! Plot bending moment MZ
  ~PLLSFOR,M,Z,-1
! Check for lateral bending
  ~CHKSTL,BUCK_BND,-Z,FULL

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 3
  NComp_ch =  0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
!--------------------------------------------------------------------------------------
  LABEL(1,1) = 'MSD'
  LABEL(2,1) = 'MBRD'
  LABEL(3,1) = 'CRT_TOT'

! Correct values
!--------------------------------------------------------------------------------------
  VALUE(1,1)=-540
  VALUE(2,1)= 256.2
  VALUE(3,1)= 2.107

! Obtained values
!--------------------------------------------------------------------------------------
 ~PLLSSTL,MSD
  *GET,VALUE(1,2),ELEM,3,ETAB,CFETAB_J
 ~PLLSSTL,MBRD
  *GET,VALUE(2,2),ELEM,3,ETAB,CFETAB_J
 ~PLLSSTL,CRT_TOT
  *GET,VALUE(3,2),ELEM,3,ETAB,CFETAB_J

! Warning and error tolerances
  TOLER( 1, 1)= 1E-4   $   TOLER( 1, 2)= 1E-4
  TOLER( 2, 1)= 2E+1   $   TOLER( 2, 2)= 2E+1
  TOLER( 3, 1)= 1E-1   $   TOLER( 3, 2)= 1E-1

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC

Results

Label	Target	CivilFEM	Ratio	Tolerance
MSD	-540	-540	1.000	0.0001
MBRD	256.2	256.21	1.000	20
CRT_TOT	2.107	2.1076	1.000	0.1

Contains proprietary and confidential information of Ingeciber, S.A.

CivilFEM Online Help

CFVR1005 - Eurocode 3 1992 test: Lateral buckling

Lateral buckling checking according to Eurocode 3 1992.

Results