CFVR1004 - Eurocode 3 1992 test: Bending and shear.

Bending and Shear checking according to Eurocode 3.

A fixed steel beam is subjected to a surface load of 1000 KN.
The beam has a length of 1m.
The cross section is a IPE 400.
The beam is made of Fe 430 steel which has a fy of 275000 kN/m².
The aim of the example is to obtain the cross section classification and shear criterion according to Eurocode 3 1992.

Element types used in the model: BEAM3

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

The example can be launched on an educational license.

KEYWORDS

Beam

Cross Section

Steel

Code Checking/Design

Eurocode 3

Model Statistics
Number of elements	24
Number of nodes	25
Number of civil materials	1
Number of cross sections	1
Number of shell vertices	0

Log file: CFVR1004.DAT

  FINISH
  ~CFCLEAR,,1
  NomFile='CFVR1004'
  /TITLE, %NomFile%, Eurocode 3 1992 test: Bending and Shear

! ---------------------------------------------------------------------------------
! Model definition and solve
! ---------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
  ~UNITS,,LENG,M
  ~UNITS,,TIME,S
  ~UNITS,,FORC,KN
  ~CODESEL,EC3-92

/PREP7
! Preprocessor
! --------------------------------------------------
! Materials
  ~CFMP,1,LIB,STEEL,EC3,Fe 430   !Fe 430 (EC3)
! Element Types
  ET,1,BEAM3         ! Type 1: 2D Beam
! Cross sections
  ~SSECLIB,1,1,1,14     !IPE 400

! Beam Properties
 ~BMSHPRO,1,BEAM,1,1,,,3,1,0,,

! Nodes
  N, 1
  N,25,1
  FILL, 1,25
! Elements
  E,1,2
  EGEN,24,1,1
  EPLOT
/SOLU
! Solution
! --------------------------------------------------
! Displacements
  D, 1,ALL
  D,25,ALL
! Apply Load
  SFBEAM,ALL,1,PRES,1000
! Solve
  SOLVE
/POST1
! Postprocessor
! --------------------------------------------------
! Read results
  ~CFSET,,1,1       !Read the first load step
! Plot bending moment MZ
  ~PLLSFOR,M,Z,-1
! Check in Bending + Shear
  ~CHKSTL,BEND_SHR,-Z,PARTIAL

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 8
  NComp_ch =  0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
!--------------------------------------------------------------------------------------
  LABEL(1,1) = 'CLASS'
  LABEL(2,1) = 'S_AREA'
  LABEL(3,1) = 'VplRd'
  LABEL(4,1) = 'Vsd'
  LABEL(5,1) = 'RHO'
  LABEL(6,1) = 'MvRd'
  LABEL(7,1) = 'Msd'
  LABEL(8,1) = 'Crit'

! Correct values
!--------------------------------------------------------------------------------------
  VALUE(1,1)=1
  VALUE(2,1)=42.691E-4
  VALUE(3,1)=616.19
  VALUE(4,1)=-500
  VALUE(5,1)=0.38797459
  VALUE(6,1)=275.3625
  VALUE(7,1)=83.3333333
  VALUE(8,1)=0.30263138

! Obtained values
!--------------------------------------------------------------------------------------
 ~PLLSSTL,CLASS
  *GET,VALUE(1,2),ELEM,1,ETAB,CLASS_I
 ~PLLSSTL,S_AREA
  *GET,VALUE(2,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,VPLRD
  *GET,VALUE(3,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,VSD
  *GET,VALUE(4,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,RHO
  *GET,VALUE(5,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,MVRD
  *GET,VALUE(6,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,MSD
  *GET,VALUE(7,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,CRT_TOT
  *GET,VALUE(8,2),ELEM,1,ETAB,CFETAB_I

! Warning and error tolerances
  TOLER( 1, 1)= 0    $ TOLER( 1, 2)= 0
  TOLER( 2, 1)= 1E-6 $ TOLER( 2, 2)= 1E-3
  TOLER( 3, 1)= 1    $ TOLER( 3, 2)= 1E2
  TOLER( 4, 1)= 1    $ TOLER( 4, 2)= 1E2
  TOLER( 5, 1)= 1E-4 $ TOLER( 5, 2)= 1E-2
  TOLER( 6, 1)= 1    $ TOLER( 6, 2)= 1E2
  TOLER( 7, 1)= 1    $ TOLER( 7, 2)= 1E1
  TOLER( 8, 1)= 1E-4 $ TOLER( 8, 2)= 1E-2

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC

Results

Label	Target	CivilFEM	Ratio	Tolerance
CLASS	1	1	1.000	0
S_AREA	0.0042691	0.0042691	1.000	0.001
VplRd	616.19	616.19	1.000	100
Vsd	-500	-500	1.000	100
RHO	0.38797	0.38797	1.000	0.01
MvRd	275.36	275.36	1.000	100
Msd	83.333	83.333	1.000	10
Crit	0.30263	0.30263	1.000	0.01

Contains proprietary and confidential information of Ingeciber, S.A.

CivilFEM Online Help

CFVR1004 - Eurocode 3 1992 test: Bending and shear.

Bending and Shear checking according to Eurocode 3.

Results