CFVR5230 - Prestressed rectangular solid model.

Prestress loads on rectangular solid model.

The model is a prestressed rectangular solid segment of 5 m length.
The beam is made of C35/45 concrete and the tendon is made of Y1860C steel.
The section is rectangular.
The aim of the example is to verify the prestress loads on rotated nodal coordinate systems.

Element types used in the model: SOLID45

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

The example cannot be launched on an educational license.

KEYWORDS

Free Tendon

Prestressed Concrete

Model Statistics
Number of elements	320
Number of nodes	525
Number of civil materials	2
Number of cross sections	0
Number of shell vertices	0

Log file: CFVR5230.DAT

  FINISH
  ~CFCLEAR,,1
  ~CFACTIV,PRSC,Y
  ~CFACTIV,NLBR,Y 
  NomFile='CFVR5230'
  /TITLE, CFVR5230 - Prestressed rectangular solid model.

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------

~UNITS,SI

! Parameters
a=1            ! Section Width
b=1            ! Section Height
L=5            ! Length of the model
ESIZ=0.25      ! Element size
N_Ax=8.00E6    ! Axial force

/PREP7 

! Elements
ET,1,45           ! SOLID 45

! Real contants 
R,1,0             ! Real constant for solid element (unused)

! Materials
~CFMP,1,LIB,CONCRETE,EC2,C35/45      ! EC2 C35/40
~CFMP,2,LIB,PREST,EN10138,Y1860C     ! EHE Y1860C
~CFMP,2,Prest,A ,,0
~CFMP,2,Prest,K ,,0
~CFMP,2,Prest,MU,,0 
~CFMP,1,USER
~CFMP,1,Concr   ,ExLn    ,,3.3282e+010  

! GEOMETRY AND MESHING
BLOCK,-a/2,a/2,-b/2,b/2,0,5

MSHAPE,0,3D 
MSHKEY,1
ESIZE,ESIZ,0,
VMESH,ALL
/VIEW,  1, -0.54, 0.33, 0.78
EPLOT
/IMAGE, SAVE, %NomFile%,BMP

CSYS,0
! Tendon geometry
K,100,0.0,0.0,0.0
K,101,0.0,0.0,L
LSEL,NONE
L,100,101
LESIZE,13,ESIZ,,

NSEL,ALL
ESEL,ALL

LOCAL,11,  , , , ,30,45,10
NROTAT,all,all
CSYS,0
/SOLU

~GENTEN,1,N_Ax,100,0.1,2,1,0
~TENLD,1   ! Loads free prestressing tendon into the model

/SOLU
! Boundary conditions
NSEL,S,LOC,Z,0
D,ALL,ALL

ALLSEL
SOLVE

/POST1
~CFSET,,1
Node1=Node(0,0,5)

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp    = 5
  NComp_ch = 0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
!--------------------------------------------------------------------------------------
  LABEL( 1)  = 'FX'
  LABEL( 2)  = 'FY'
  LABEL( 3)  = 'FZ'
  LABEL( 4)  = 'SY'
  LABEL( 5)  = 'USUM'

! Correct data, obtained data
!--------------------------------------------------------------------------------------
  VALUE( 1,1) =    982302.43    $  *GET,value( 1,2),NODE,Node1,F,FX
  VALUE( 2,1) =  -5656854.25    $  *GET,value( 2,2),NODE,Node1,F,FY
  VALUE( 3,1) =  -5570913.92    $  *GET,value( 3,2),NODE,Node1,F,FZ
  VALUE( 4,1) =  -53957572.2    $  *GET,value( 4,2),NODE,Node1,S,Y
  VALUE( 5,1) =  2.61835E-03    $  *GET,value( 5,2),NODE,Node1,U,SUM

! Warning and error tolerances
  *DO,II,1,4
    TOLER(II,1)  = 1E2
    TOLER(II,2)  = 1E2
  *ENDDO

  TOLER(5,1)  = 1E-5    $    TOLER(5,2)  = 1E-5

!--------------------------------------------------------------------------------------
! Result comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC

Results

Label	Target	CivilFEM	Ratio	Tolerance
FX	9.823e+005	9.823e+005	1.000	100
FY	-5.6569e+006	-5.6569e+006	1.000	100
FZ	-5.5709e+006	-5.5709e+006	1.000	100
SY	-5.3958e+007	-5.3958e+007	1.000	100
USUM	0.0026184	0.0026184	1.000	1e-005

Contains proprietary and confidential information of Ingeciber, S.A.

CivilFEM Online Help

CFVR5230 - Prestressed rectangular solid model.

Prestress loads on rectangular solid model.

Results