Element types used in the model: BEAM4

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

  FINISH
  ~CFCLEAR,,1
   NomFile='CFVR2817'
  /TITLE,%NomFile%, TORSION DESIGN ACCORDING TO IS456

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,,LENG,M
  ~UNITS,,TIME,S
  ~UNITS,,FORC,MP
  ~CODESEL,EC3-92,IS456,,,EC8-94
  ~CFCONFG,DINTER,WMIN,0.1

! Preprocessor
  /PREP7

! Parameters
  L= 1         ! Length in m
  b= 0.4       ! Cross-section width in m.
  h= 0.3       ! Depth in m.
  T= 2.5       ! Torsional moment in Mp*m
  Q= 5.5       ! Maximum concomitant design shear force in Mp

! Material Definition
  ~CFMP,1,LIB,CONCRETE,IS456,M50
  ~CFMP,2,LIB,REINF,IS1786,Fe500

! Element Type Definition
  ET,1,Beam4                            ! Element Type 1: 3D Beam

! Cross-section definition
  ~CSECDMS,1,REC,1,h,b

! Reinforcement definition
  ~RNFDEF,1,1,2,2,0,0.046,0.256E-02
  ~RNFDEF,1,2,2,4,0,0.046,0.2560E-02
  ~RNFDEF,1,SHEAR,2,,,1E-4,   ! Shear reinf.
  ~RNFDEF,1,TORSION,2,,,,,,,

! Beam properties
  ~BMSHPRO,1,BEAM,1,1,,,4,0,0,,beam properties

! Model
  N,1
  N,5,L
  FILL,1,5
  E,1,2
  EGEN,4,1,1,1

! Boundary conditions
  D,1,ALL,0

/SOLU
! Solution
  F,5,FY,-Q
  F,5,MX,T
  SOLVE               ! Calculation

/POST1
! Postprocessor
  ~CFSET,,1           ! Read first load step

! Torsion design
  ~DIMCON,SHT,BOTH

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparision number
  NComp = 3
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'MEL'
  LABEL(2,1) = 'ATT'
  LABEL(3,1) = 'REINFACT'

! Correct Values
  VALUE(1,1) = -8.074
  VALUE(2,1) = 1.026E-3
  VALUE(3,1) = 0.3038

! Comparison
 ~PLLSCON,MEL
 *GET,VALUE(1,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,ATT
 *GET,VALUE(2,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,REINFACT
 *GET,VALUE(3,2),ELEM,1,ETAB,CFETAB_I

! Warning and error tolerances
  TOLER( 1, 1)= 1E-02 $ TOLER( 1, 2)= 1E-02
  TOLER( 2, 1)= 1E-05 $ TOLER( 2, 2)= 1E-05
  TOLER( 3, 1)= 1E-03 $ TOLER( 3, 2)= 1E-03
!--------------------------------------------------------------------------------------
! Results Comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC