Element types used in the model: BEAM3

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1
   NomFile='CFVR7109'
  /TITLE,%NomFile%, SHEAR CHECKING ACCORDING TO NBR6118

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,,LENG,M
  ~UNITS,,TIME,S
  ~UNITS,,FORC,KN
  ~CODESEL,EC3-92,NBR6118,,,EC8-94

! Preprocessor
  /PREP7

! Parameters
  L=5          ! Length between supports, in m
  Q=84         ! Uniform distributed load in kN/m

! Material Definition
 ~CFMP,1,LIB,CONCRETE,NBR6118,C25
 ~CFMP,2,LIB,REINF,NBR6118,CA50

! Element Type Definition
  ET,1,Beam3                                  ! Element Type 1: 2D Beam

! Cross-section definition
 ~CSECDMS,1,T,1,0.375,0.15,0.75,0.15          !T Section
! Reinforcement definition
 ~RNFDEF,1,1,2,1,1,0.02,0.2200E-02            !Longitudinal reinforcement
 ~RNFMDF,1,1,UFC,2
 ~RNFDEF,1,SHEAR,2,,,1.0937778e-3             !Shear reinforcement
! Code properties definition
 ~SECMDF,1,NBR6118P,REC ,,5e-002              ! 5 cm Cover

! Beam properties
  ~BMSHPRO,1,BEAM,1,1,,,3,1,0

! Model Construction
  N,1                                   ! Nodes input
  N,26,L
  FILL,1,26
  E,1,2                                 ! Elements input
  EGEN,25,1,1,1
  D,1, , , , , ,UX,UY                   ! Boundary conditions
  D,26, , , , , ,UY

/SOLU
  SFBEAM,ALL,1,PRES,Q
  SOLVE               ! Calculation

/POST1

! Postprocessor
  ~CFSET,,1,1       !Read first load step

! Shear in Y checking for T sections according to NBR6118
  ~CHKCON,SHT,SHEAR

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 3
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'VRD2'
  LABEL(2,1) = 'VRD3'
  LABEL(3,1) = 'CRT_TOT'

! Correct values
  VALUE(1,1)=0.197437E3
  VALUE(2,1)=0.174181E3
  VALUE(3,1)=1.2056

! Comparison
 ~PLLSCON,VRD2
  *GET,VALUE(1,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,VRD3
  *GET,VALUE(2,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,CRT_TOT
  *GET,VALUE(3,2),ELEM,1,ETAB,CFETAB_I

! Warning and error tolerances
  TOLER( 1, 1)= 1E-02 $ TOLER( 1, 2)= 1E-02
  TOLER( 2, 1)= 1E-01 $ TOLER( 2, 2)= 1E-01
  TOLER( 3, 1)= 1E-02 $ TOLER( 3, 2)= 1E-02

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC