Element types used in the model: BEAM3

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1
  NomFile='CFVR2938'
  /TITLE,%NomFile%, SHEAR CHECKING ACCORDING TO SP 63.13330.2012

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,,LENG,M
  ~UNITS,,TIME,S
  ~UNITS,,FORC,KN
  ~CODESEL,,SP63133

! Preprocessor
  /PREP7

! Parameters
  L=5          ! Length between supports, in m
  Q=150        ! Uniform distributed load in kN/m

! Material Definition
~CFMP,1,LIB,CONCRETE,SP63133,B35
~CFMP,2,LIB,REINF,SP63133,A400  
~CFMP,2,SP_S    ,GAMs    ,,1.10 ! Changes gammaS in order to get same results than 52-101

! Element Type Definition
  ET,1,Beam3                               ! Element Type 1: 2D Beam

! Cross-section definition
~CSECDMS,1,REC,1,0.75,0.5
~SECMDF,1,SP63133P,REC,,0.05		! Mechanical cover for properties calculations   
~RNFDEF,1,SHEAR,2,,,0.5E-03     	! Shear Reinforcement=5cm2/m

! Beam properties
 ~BMSHPRO,1,BEAM,1,1,,,3,1,,,Beam Property

! Model Construction
  N,1                     ! Nodes input
  N,26,L
  FILL,1,26

  E,1,2                   ! Elements input
  EGEN,25,1,1,1

  D,1, , , , , ,UX,UY     ! Boundary conditions
  D,26,UY

/SOLU
  SFBEAM,ALL,1,PRES,Q
  SOLVE                   ! Calculation

/POST1

! Postprocessor
  ~CFSET,,1,1       ! Read first load step

! Shear in Y checking for rectangular sections according to SP 63.13330.2012
  ~CHKCON,SHT,SHEAR

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 5
  NComp_ch = 0

 ! Matrix dim.
 *DIM,LABEL,CHAR,Ncomp,1
 *DIM,LABEL_CH,CHAR,Ncomp_ch,1
 *DIM,VALUE,,Ncomp,3
 *DIM,VALUE_CH,CHAR,Ncomp_ch,3
 *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'Q1'
  LABEL(2,1) = 'QB'
  LABEL(3,1) = 'QSW'
  LABEL(4,1) = 'Q2'
  LABEL(5,1) = 'CRT_TOT'

! Correct values
  VALUE(1,1)=2059.61538
  VALUE(2,1)=227.500
  VALUE(3,1)=101.81815
  VALUE(4,1)=329.31815
  VALUE(5,1)=1.138

! Comparison
 ~PLLSCON,Q1
  *GET,VALUE(1,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,QB
  *GET,VALUE(2,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,QSW
  *GET,VALUE(3,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,Q2
  *GET,VALUE(4,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,CRT_TOT
  *GET,VALUE(5,2),ELEM,1,ETAB,CFETAB_I

! Warning and error tolerances
  TOLER( 1, 1)= 1E+01 $ TOLER( 1, 2)= 1E+01
  TOLER( 2, 1)= 1E+01 $ TOLER( 2, 2)= 1E+01
  TOLER( 3, 1)= 1E+01 $ TOLER( 3, 2)= 1E+01
  TOLER( 4, 1)= 1E+01 $ TOLER( 4, 2)= 1E+01
  TOLER( 5, 1)= 1E-01 $ TOLER( 5, 2)= 1E-01

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC