Element types used in the model: BEAM3

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1
   NomFile='CFVR7217'
 /TITLE,%NomFile%, SHEAR DESIGN ACCORDING TO ACI 349

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
~CFACTIV,NUCL,Y
~UNITS,,LENG,M
~UNITS,,TIME,S
~UNITS,,FORC,MP
~CODESEL,EC3-92,ACI349,,,EC8-94

! Preprocessor
  /PREP7

! Parameters
  L=10         ! Length between supports, in m
  b=.3         ! Cross-section width in m.
  h=.5         ! Depth in m.
  Q=4.5*1.5    ! Uniform distributed load in Mp/m

! Material Definition
 ~CFMP,1,LIB,CONCRETE,ACI,fc_4500
 ~CFMP,2,LIB,REINF,ACI,fy_60000

! Element Type Definition
  ET,1,Beam3                            ! Element Type 1: 2D Beam

! Cross-section definition
 ~CSECDMS,1,REC,1,0.5,0.3

! Reinforcement definition
 ~RNFDEF,1,1,2,4,,,0.6368E-02      ! Bot. reinf. for bending
 ~RNFDEF,1,2,2,2,,,0.2283E-02      ! Top reinf. for bending
 ~RNFDEF,1,SHEAR,2,,.1E-4,         ! Shear reinf.
! Code properties
 ~SECMDF,1,ACI349PR,D_Y,,0.45
 ~SECMDF,1,ACI349PR,D_Z,,0.25
! Beam & Shell properties
  ~BMSHPRO,1,BEAM,1,,,,3,,,,Beam property

! Model Construction
  N,1                                   ! Nodes input
  N,21,L
  FILL,1,21
  E,1,2                                 ! Elements input
  EGEN,20,1,1,1
  D,1, , , , , ,UX,UY                   ! Boundary conditions
  D,21, , , , , ,UY

/SOLU
  SFBEAM,ALL,1,PRES,Q
  SOLVE               ! Calculation

/POST1

! Postprocessor
  ~CFSET,,1,1       ! Read first load step

! Shear in Y design according to ACI 349
  ~DIMCON,SHT,SHEAR,0, , , , ,1

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 3
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'VC'
  LABEL(2,1) = 'VS'
  LABEL(3,1) = 'ASSH'

! Correct values
  VALUE(1,1)=12.78
  VALUE(2,1)=26.8
  VALUE(3,1)=1.409E-3

! Comparison
 ~PLLSCON,VC
 *GET,VALUE(1,2),ELEM,20,ETAB,CFETAB_J
 ~PLLSCON,VS
  *GET,VALUE(2,2),ELEM,20,ETAB,CFETAB_J
 ~PLLSCON,ASSH
  *GET,VALUE(3,2),ELEM,20,ETAB,CFETAB_J

! Warning and error tolerances
  TOLER( 1, 1)= 1E-01 $ TOLER( 1, 2)= 1E-01
  TOLER( 2, 1)= 1E-00 $ TOLER( 2, 2)= 1E-00
  TOLER( 3, 1)= 1E-04 $ TOLER( 3, 2)= 1E-04

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC