CFVR7321 - Steel checking according to ASME BPVC III Subsection NF

Bending checking of a cantilever steel beam

A steel cantilever beam with channel shape section is subjected to a vertical force in both directions at free end. Ct reduction coefficient is taken as 0.85
Determine the total criterion according to ASME BPVC III Subsection NF.

Element types used in the model: BEAM188

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

The example can be launched on an educational license.

KEYWORDS

Beam

Cross Section

Code Checking/Design

Steel

ASME BPVC III NF

Model Statistics
Number of elements	1
Number of nodes	2
Number of civil materials	1
Number of cross sections	1
Number of shell vertices	0

Log file: CFVR7321.DAT

FINISH
~CFCLEAR,,1

   NomFile='CFVR7321'
 /TITLE, %NomFile%, Bending checking ASME BPVC III subsection NF
! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
~CFACTIV,NUCL,Y
~CODESEL,ASME_NF,EC2-91,EC2-91,,EC8-94

/PREP7

ET,1,Beam188,,,2

~CFMP,1,LIB,STEEL,ASTM,A441
~CFMP,1,USER
~CFMP,1,STEEL,STYPE,,1  ! Austenitic

~SSECDMS,1,C,1,0.6,0.01,0.25,0.015
~MEMBPRO,1,ASME_NF,ALL, 5.0, 2.0, 2.0, 1.0, 1.0, 1.0, 1.0, 1, 1, 1
~BMSHPRO,1,BEAM,1,1,,,188,1,0,,Beam 1

N,1,
N,2,0,5
E,1,2

/SHRINK,0
/ESHAPE,1.0

EPLOT

D,1,ALL

F,2,FX,-40000
F,2,FZ,-10000

/SOLU
SOLVE

/POST1
~CFSET,0,1,LAST

~CHKSTL,BENDING,Z
~CHKSTL,BENDING,Y

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 8
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'QS_Z'
  LABEL(2,1) = 'QA_Z'
  LABEL(3,1) = 'FB_Z'
  LABEL(4,1) = 'CRT_Z'
  LABEL(5,1) = 'QS_Y'
  LABEL(6,1) = 'QA_Y'
  LABEL(7,1) = 'FB_Y'
  LABEL(8,1) = 'CRT_Y'

! Correct values
  VALUE(1,1)=0.90
  VALUE(2,1)=1.00
  VALUE(3,1)=103421000
  VALUE(4,1)=0.729
  VALUE(5,1)=1.00
  VALUE(6,1)=1.00
  VALUE(7,1)=206843000
  VALUE(8,1)=0.498

! Comparison
 ~CFSET,1
 ~PLLSSTL,QS
 *GET,VALUE(1,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,QA
 *GET,VALUE(2,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,FB
 *GET,VALUE(3,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,CRT_TOT
 *GET,VALUE(4,2),ELEM,1,ETAB,CFETAB_I
 ~CFSET,2
 ~PLLSSTL,QS
 *GET,VALUE(5,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,QA
 *GET,VALUE(6,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,FB
 *GET,VALUE(7,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,CRT_TOT
 *GET,VALUE(8,2),ELEM,1,ETAB,CFETAB_I

! Warning and error tolerances
  TOLER( 1, 1)= 1E-03   $ TOLER( 1, 2)= 1E-03
  TOLER( 2, 1)= 1E-03   $ TOLER( 2, 2)= 1E-03
  TOLER( 3, 1)= 1E+03   $ TOLER( 3, 2)= 1E+03	! Rounding error accepted	
  TOLER( 4, 1)= 1E-03   $ TOLER( 4, 2)= 1E-03	
  TOLER( 5, 1)= 1E-03   $ TOLER( 5, 2)= 1E-03	
  TOLER( 6, 1)= 1E-03   $ TOLER( 6, 2)= 1E-03
  TOLER( 7, 1)= 1E+03   $ TOLER( 7, 2)= 1E+03	! Rounding error accepted
  TOLER( 8, 1)= 1E-03   $ TOLER( 8, 2)= 1E-03

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC

Results

Label	Target	CivilFEM	Ratio	Tolerance
QS_Z	0.9	0.89999	1.000	0.001
QA_Z	1	1	1.000	0.001
FB_Z	1.0342e+008	1.0342e+008	1.000	1000
CRT_Z	0.729	0.7287	1.000	0.001
QS_Y	1	1	1.000	0.001
QA_Y	1	1	1.000	0.001
FB_Y	2.0684e+008	2.0684e+008	1.000	1000
CRT_Y	0.498	0.49847	0.999	0.001

Contains proprietary and confidential information of Ingeciber, S.A.

CivilFEM Online Help

CFVR7321 - Steel checking according to ASME BPVC III Subsection NF

Bending checking of a cantilever steel beam

Results