Element types used in the model: BEAM188

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

 FINISH
 ~CFCLEAR,,1
 NomFile='CFVR8651'
 /TITLE, %NomFile%, AISC15: Compression Check 
!--------------------------------------------------------------------------------------
! Model definition
!--------------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
  ~UNITS,,LENG,IN
  ~UNITS,,TIME,S
  ~UNITS,,FORC,KIPS! in, sec, Kips
  ~CODESEL,AISC15

! Parameters
  P  = -840		! Axial force kips
  Fyy = 50         ! ksi
  Fuu= 65         ! ksi

/PREP7
! Preprocessor
! --------------------------------------------------
! Materials
 ~CFMP,1,LIB,STEEL,ASTM,A36 
!  ASTM A992 
 ~CFMP,1,NAME,,,ASTM A992
 ~CFMP,1,USER
 ~CFMP,1,AISC15  ,Fy,,Fyy ,1,0,0
 ~CFMP,1,AISC15  ,Fu,,Fuu ,1,0,0
 
! Element Types
  ET,1,188  ! Type 1: 3D Beam
  
! Cross Section
  ~SSECLIB,1,1,51,187   ! W 14x90  

! member property: K=KTOR=0.5 to get effective length = 15 ft
  ~MEMBPRO,1,AISC15,ALL,30.00*12,0.50,1.00,0.50,1.000,30.00*12,  

! Beam & Shell Property
  ~BMSHPRO,1,BEAM,1,1,,,188,1,0,,Beam 1
  
! Nodes
  N,1
  N,2,,2
  
! Elements
  SECNUM,1
  REAL,1
  E,1,2  

  /SOLU
! Solution
! --------------------------------------------------
! Constrains
  D,1,ALL
  
! Apply Load
  F,2,FY,P
  
! Solve
  SOLVE
  
  /POST1
! Postprocessor
! --------------------------------------------------
! Read results
  ~CFSET,,1                ! First load case
  
! Checking
 ~CHKSTL,COMPRESS,Z,LRFD   
 ~CHKSTL,COMPRESS,Z,ASD 
 
 !--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 6
  NComp_ch = 0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'FCR'
  LABEL(2,1) = 'PN'
  LABEL(3,1) = 'FE'
  LABEL(4,1) = 'CLS_COMP'
  LABEL(5,1) = 'CRT_TOT_LRFD'
  LABEL(6,1) = 'CRT_TOT_ASD'

! Correct values
  VALUE(1,1)=38.90  ! Flexural buckling stress (Spec. Eq. E3-2) 
  VALUE(2,1)=1030   ! Nominal Compressive Strength (Spec. Eq. E3-1) 
  VALUE(3,1)=83.3   ! Elastic  critical  buckling  stress (Spec. Eq. E3-4) 
  VALUE(4,1)=1.00   ! FLANGES AND WEB are nonslender
  VALUE(5,1)=0.906  ! LRFD CRITERION   840/0.90*PN
  VALUE(6,1)=1.36   ! ASD CRITERION    840/(1030/1.67)

! Comparison

~CFSET,1   ! LRFD 
 ~CFGET,VALUE(1,2),ELEMENT,1,RESULT,FCR,I 
 ~CFGET,VALUE(2,2),ELEMENT,1,RESULT,PN,I 
 ~CFGET,VALUE(3,2),ELEMENT,1,RESULT,FE,I 
 ~CFGET,VALUE(4,2),ELEMENT,1,RESULT,CLS_COMP,I
 ~CFGET,VALUE(5,2),ELEMENT,1,RESULT,CRT_TOT,I
 
~CFSET,2  ! ASD 
 ~CFGET,VALUE(6,2),ELEMENT,1,RESULT,CRT_TOT,I

! Warning and error tolerances
*DO,JJ,1,6
 TOLER(JJ,1)= 0.04*VALUE(JJ,1) $ TOLER(JJ,2)= 0.04*VALUE(JJ,1)
*ENDDO

  
!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC