Element types used in the model: BEAM3

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

  FINISH
  ~CFCLEAR,,1
  NomFile='CFVR2807'
 /TITLE,%NomFile%, SHEAR CHECKING ACCORDING TO IS456

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,,LENG,m
  ~UNITS,,TIME,S
  ~UNITS,,FORC,MP
  ~CODESEL,EC3-92,IS456,,,EC8-94

! Preprocessor
  /PREP7

! Parameters
  L = 10     ! Length between supports, in m
  b = 0.3    ! Cross-section width in m.
  h = 0.5    ! Depth in m.
  Q = 7.5    ! Uniform distributed load in Mp/m

! Material Definition
  ~CFMP,1,LIB,CONCRETE,IS456,M40
  ~CFMP,2,LIB,REINF,IS1786,Fe500

! Element Type Definition
  ET,1,Beam3                            ! Element Type 1: 2D Beam

! Cross-section definition
 ~CSECDMS,1,REC,1,h,b

! Reinforcement definition
 ~RNFDEF,1,SHEAR,2, , , , , , ,4.416e-002,6,2,2

! Beam properties
  ~BMSHPRO,1,BEAM,1,,,,3,,,,beam property

! Model
  N,1
  N,21,L
  FILL,1,21
  E,1,2
  EGEN,20,1,1,1
! Boundary conditions
  D, 1,UX,0
  D, 1,UY,0
  D,21,UY,0

/SOLU
! Solution
  SFBEAM,ALL,1,PRES,Q
  SOLVE

/POST1
! Postprocessor
  ~CFSET,,1           ! Read first load step

! Shear in Y checking according to IS456
  ~CHKCON,SHT,SHEAR

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparision number
  NComp = 4
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'VUT'
  LABEL(2,1) = 'VUS'
  LABEL(3,1) = 'VUC'
  LABEL(4,1) = 'CRT_TOT'

! Correct Values
  VALUE(1,1) = 25.9085
  VALUE(2,1) = 21.6869
  VALUE(3,1) =  4.2216
  VALUE(4,1) =  1.4474

! Comparison
 ~PLLSCON,VUT
 *GET,VALUE(1,2),ELEM,20,ETAB,CFETAB_J
 ~PLLSCON,VUS
 *GET,VALUE(2,2),ELEM,20,ETAB,CFETAB_J
 ~PLLSCON,VUC
 *GET,VALUE(3,2),ELEM,20,ETAB,CFETAB_J
 ~PLLSCON,CRT_TOT
 *GET,VALUE(4,2),ELEM,20,ETAB,CFETAB_J

! Warning and error tolerances
  TOLER( 1, 1)= 1E-03 $ TOLER( 1, 2)= 1E-03
  TOLER( 2, 1)= 1E-00 $ TOLER( 2, 2)= 1E-00
  TOLER( 3, 1)= 1E-01 $ TOLER( 3, 2)= 1E-01
  TOLER( 4, 1)= 1E-01 $ TOLER( 4, 2)= 1E-01
!--------------------------------------------------------------------------------------
! Results Comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC