Element types used in the model: BEAM188

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1
  NomFile='CFVR1027'
  /TITLE, %NomFile%, EC3-05 test: Axial and Shear Force and Biaxial Bending

! ---------------------------------------------------------------------------------
! Model definition and solve
! ---------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
  ~UNITS,SI
  ~CODESEL,EC3-05,EC2-08,,,EC8-94
/PREP7
! Materials
  ~CFMP,1,LIB,STEEL,EC3,Fe 510
  ~CFMP,1,EC3     ,GAMM0   ,,1
  ~CFMP,1,EC3     ,GAMM1   ,,1

! Element type
  ET,1,188 ! Type 1: 3D Beam
  KEYOPT,1,3,2

! Cross Sections
  ~SSECLIB,1,1,6,6   !HE 200 B

! Member Properties
  ~MEMBPRO,1,EC3,ALL,5.000,1.000,1.000,1.365,0.5530,0.000,1.000,1.000,1.000,,0,1.000,1.000,1  
  ~MEMBPRO,1,NLMOD,ALL,0  
  ~MEMBPRO,1,NAME,Member Property 1   

! Beam properties
  ~BMSHPRO,1,BEAM,1,1,,,188,1,0,,Beam 1

! Geometry
  K,1
  K,2,5
  L,1,2
  
! Mesh
  LESIZE,ALL, , ,50, , , , ,1 
  LMESH,all
  NSEL,S,LOC,X,2.5  
  EPLOT
/SOLU
! Restraints
  DK,1,UX
  DK,1,UY
  DK,1,UZ
  DK,1,ROTX
  DK,1,ROTY
  DK,2,UY
  DK,2,UZ
  DK,2,ROTX
  DK,2,ROTY
! Apply Load
  NSEL,S,LOC,X,2.5  
  F,all,FY,-100000
  ALLSEL
! Solve
  SOLVE
/POST1
! Read results
  ~CFSET,,1,1       ! Read the first load step
! Check Bending buckling
  ~CHKSTL,BUCK_BND,-Z,FULL

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 5
  NComp_ch =  0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
!--------------------------------------------------------------------------------------
  LABEL( 1,1) = 'CHI_LT'
  LABEL( 2,1) = 'PHI_LT'
  LABEL( 3,1) = 'LAM_LT'
  LABEL( 4,1) = 'ALP_LT'
  LABEL( 5,1) = 'MCR'

! Correct values
!-------------------------------------------------------------------------------------
  VALUE( 1,1)=   0.84
  VALUE( 2,1)=   0.81
  VALUE( 3,1)=   0.72
  VALUE( 4,1)=   0.21
  VALUE( 5,1)=   438920

! Obtained values
!--------------------------------------------------------------------------------------

 ~CFGET,VALUE( 1,2),ELEMENT,1,RESULT,CHI_LT,I
 ~CFGET,VALUE( 2,2),ELEMENT,1,RESULT,PHI_LT,I
 ~CFGET,VALUE( 3,2),ELEMENT,1,RESULT,LAM_LT,I
 ~CFGET,VALUE( 4,2),ELEMENT,1,RESULT,ALP_LT,I
 ~CFGET,VALUE( 5,2),ELEMENT,1,RESULT,MCR,I


! Warning and error tolerances
  TOLER( 1,1)= 1E-2   $ TOLER( 1,2)= 1E-2 
  TOLER( 2,1)= 1E-2   $ TOLER( 2,2)= 1E-2
  TOLER( 3,1)= 1E-2   $ TOLER( 3,2)= 1E-2
  TOLER( 4,1)= 1E-2   $ TOLER( 4,2)= 1E-2
  TOLER( 5,1)= 1E+3   $ TOLER( 5,2)= 1E+3

 !--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC