Element types used in the model: BEAM4

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

  FINISH
  ~CFCLEAR,,1
  NomFile='CFVR2217'
  /TITLE, %NomFile%, TORSION DESIGN ACCORDING TO BS8110

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,,LENG,M
  ~UNITS,,TIME,S
  ~UNITS,,FORC,MP
  ~CODESEL,,BS8110

! Preprocessor
  /PREP7

! Parameters
  L= 1         ! Length in m
  b= 0.4       ! Cross-section width in m.
  h= 0.3       ! Depth in m.
  T= 1.5       ! Torsional moment in Mp*m
  Q= 5.5       ! Maximum concomitant design shear force in Mp

! Material Definition
  ~CFMP,1,LIB,CONCRETE,BS8110,C50
  ~CFMP,2,LIB,REINF,BS8110,Gr460A

! Element Type Definition
  ET,1,Beam4                            ! Element Type 1: 3D Beam

! Cross-section definition
  ~CSECDMS,1,REC,1,h,b

! Reinforcement definition
 ~RNFDEF,1,TORSION,2

! Beam properties
  ~BMSHPRO,1,BEAM,1,1,,,4,0,0,,Beam properties

! Model
  N,1
  N,5,L
  FILL,1,5
  E,1,2
  EGEN,4,1,1,1
! Boundary conditions
  D,1,ALL,0

/SOLU
! Solution
  F,5,FY,-Q
  F,5,MX,T
  SOLVE               ! Calculation

/POST1
! Postprocessor
  ~CFSET,,1,1

! Torsion design
  ~DIMCON,SHT,TORSION

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparision number
  NComp = 3
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'TU1'
  LABEL(2,1) = 'ASTT'
  LABEL(3,1) = 'ASLT'

! Correct Values
  VALUE(1,1) = 4.000
  VALUE(2,1) = 6.526E-4
  VALUE(3,1) = 3.524E-4

! Comparison
 ~PLLSCON,TU1
 *GET,VALUE(1,2),ELEM,3,ETAB,CFETAB_J
 ~PLLSCON,ASTT
 *GET,VALUE(2,2),ELEM,3,ETAB,CFETAB_J
 ~PLLSCON,ASLT
 *GET,VALUE(3,2),ELEM,3,ETAB,CFETAB_J

! Warning and error tolerances
  TOLER( 1,1)= 1E-2 $ TOLER( 1,2)= 1E-2  ! Rounding error accepted
  TOLER( 2,1)= 1E-5 $ TOLER( 2,2)= 1E-5
  TOLER( 3,1)= 1E-5 $ TOLER( 3,2)= 1E-5

!--------------------------------------------------------------------------------------
! Results Comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC